From: "Matthew Smith" <matthew@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-util/rebar/
Date: Tue, 16 Jan 2024 08:40:19 +0000 (UTC) [thread overview]
Message-ID: <1705394375.111ca980a4acf299e493ed38af825bac1f3160ee.matthew@gentoo> (raw)
commit: 111ca980a4acf299e493ed38af825bac1f3160ee
Author: Haelwenn (lanodan) Monnier <contact <AT> hacktivis <DOT> me>
AuthorDate: Sun Jan 14 15:15:05 2024 +0000
Commit: Matthew Smith <matthew <AT> gentoo <DOT> org>
CommitDate: Tue Jan 16 08:39:35 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=111ca980
dev-util/rebar: Add := to erlang dependency
No changes to installed files, so not dropping back to ~arch.
Also, drop rebar-bin blocker as it has been out of the tree for
~1.5 years (thanks mm1ke).
Closes: https://bugs.gentoo.org/913601
Signed-off-by: Haelwenn (lanodan) Monnier <contact <AT> hacktivis.me>
Closes: https://github.com/gentoo/gentoo/pull/34800
Signed-off-by: Matthew Smith <matthew <AT> gentoo.org>
dev-util/rebar/rebar-3.22.1-r1.ebuild | 68 +++++++++++++++++++++++++++++++++++
1 file changed, 68 insertions(+)
diff --git a/dev-util/rebar/rebar-3.22.1-r1.ebuild b/dev-util/rebar/rebar-3.22.1-r1.ebuild
new file mode 100644
index 000000000000..76fb5f3577b0
--- /dev/null
+++ b/dev-util/rebar/rebar-3.22.1-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN=${PN}3
+MECK_PV=0.8.13 # see rebar.config
+
+inherit bash-completion-r1
+
+DESCRIPTION="A sophisticated build-tool for Erlang projects that follows OTP principles"
+HOMEPAGE="https://www.rebar3.org https://github.com/erlang/rebar3"
+SRC_URI="
+ https://github.com/erlang/${MY_PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz
+ test? ( https://repo.hex.pm/tarballs/meck-${MECK_PV}.tar )
+"
+S="${WORKDIR}"/${MY_PN}-${PV}
+
+LICENSE="Apache-2.0 MIT BSD"
+SLOT="3"
+KEYWORDS="amd64 ~arm ~ia64 ppc ppc64 sparc x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+# Note: /usr/bin/rebar is a ZIP archive of BEAM files so := is needed
+# see #913601
+RDEPEND="
+ dev-lang/erlang:=[ssl]
+"
+DEPEND="${RDEPEND}"
+
+src_unpack() {
+ unpack ${P}.tar.gz
+
+ if use test; then
+ mkdir "${S}"/vendor/meck || die
+ tar -O -xf "${DISTDIR}"/meck-${MECK_PV}.tar contents.tar.gz |
+ tar -xzf - -C "${S}"/vendor/meck
+ assert
+ fi
+}
+
+src_compile() {
+ ./bootstrap || die
+}
+
+src_test() {
+ ./rebar3 ct || die
+}
+
+src_install() {
+ dobashcomp apps/rebar/priv/shell-completion/bash/${MY_PN}
+ dobin ${MY_PN}
+ dodoc rebar.config.sample
+ doman manpages/${MY_PN}.1
+
+ # MIX_REBAR3: Used by elixir
+ newenvd - 98rebar3 <<-EOF
+ MIX_REBAR3=${EPREFIX}/usr/bin/${MY_PN}
+EOF
+
+ insinto /usr/share/fish/completion
+ newins apps/rebar/priv/shell-completion/fish/${MY_PN}.fish ${MY_PN}
+
+ insinto /usr/share/zsh/site-functions
+ doins apps/rebar/priv/shell-completion/zsh/_${MY_PN}
+}
next reply other threads:[~2024-01-16 8:40 UTC|newest]
Thread overview: 54+ messages / expand[flat|nested] mbox.gz Atom feed top
2024-01-16 8:40 Matthew Smith [this message]
-- strict thread matches above, loose matches on Subject: below --
2024-08-30 10:03 [gentoo-commits] repo/gentoo:master commit in: dev-util/rebar/ Matthew Smith
2024-08-04 17:01 Jakov Smolić
2024-04-13 12:51 Matthew Smith
2024-03-24 16:24 Matthew Smith
2023-12-09 13:20 Michał Górny
2023-10-04 15:28 Sam James
2023-10-04 10:00 Matthew Smith
2023-05-18 17:06 Matthew Smith
2023-01-09 8:44 Florian Schmaus
2023-01-09 8:44 Florian Schmaus
2023-01-01 16:05 Sam James
2022-11-20 8:32 Matthew Smith
2022-11-18 8:26 Matthew Smith
2022-10-16 10:23 Matthew Smith
2022-09-09 9:48 Matthew Smith
2022-08-09 4:00 Arthur Zamarin
2022-07-09 7:35 Matthew Smith
2022-07-09 7:35 Matthew Smith
2022-05-23 12:03 Jakov Smolić
2022-04-12 7:26 Matthew Smith
2022-04-12 7:26 Matthew Smith
2020-11-28 18:37 Aaron Bauman
2020-06-21 17:12 Agostino Sarubbo
2020-06-21 16:54 Agostino Sarubbo
2020-06-20 15:45 Thomas Deutschmann
2019-12-07 13:47 Sergei Trofimovich
2019-11-17 4:16 Matt Turner
2019-01-31 7:25 Sergei Trofimovich
2019-01-30 13:20 Tobias Klausmann
2019-01-27 15:14 Pacho Ramos
2019-01-27 15:13 Pacho Ramos
2018-08-05 20:15 Sergei Trofimovich
2018-06-25 13:36 Tobias Klausmann
2018-06-17 10:21 Sergei Trofimovich
2018-05-27 16:29 Mikle Kolyada
2018-05-27 13:01 Thomas Deutschmann
2017-11-15 22:13 Patrice Clement
2017-02-15 23:23 Michael Weber
2017-01-25 19:39 Dirkjan Ochtman
2017-01-20 21:34 Dirkjan Ochtman
2016-11-19 21:10 Dirkjan Ochtman
2016-11-19 21:10 Dirkjan Ochtman
2016-08-20 20:00 Anthony G. Basile
2016-08-20 2:19 Matthias Maier
2016-07-03 16:16 Sergei Trofimovich
2016-07-03 14:53 Sergei Trofimovich
2016-06-11 10:45 Jeroen Roovers
2016-05-29 17:52 Anthony G. Basile
2016-05-21 8:03 Markus Meier
2016-02-08 9:04 Dirkjan Ochtman
2016-02-08 9:04 Dirkjan Ochtman
2015-12-28 8:08 Dirkjan Ochtman
2015-09-20 8:54 Dirkjan Ochtman
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1705394375.111ca980a4acf299e493ed38af825bac1f3160ee.matthew@gentoo \
--to=matthew@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox