[gentoo-commits] repo/gentoo:master commit in: dev-util/poke/

public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed

From: "Arsen Arsenović" <arsen@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-util/poke/
Date: Sun, 14 May 2023 09:32:58 +0000 (UTC)	[thread overview]
Message-ID: <1684056749.6c8a26a3043640120b737951648b2b053fd3eca7.arsen@gentoo> (raw)

commit:     6c8a26a3043640120b737951648b2b053fd3eca7
Author:     Arsen Arsenović <arsen <AT> gentoo <DOT> org>
AuthorDate: Sat May 13 19:17:37 2023 +0000
Commit:     Arsen Arsenović <arsen <AT> gentoo <DOT> org>
CommitDate: Sun May 14 09:32:29 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6c8a26a3

dev-util/poke: add 3.2

Signed-off-by: Arsen Arsenović <arsen <AT> gentoo.org>

 dev-util/poke/Manifest        |   1 +
 dev-util/poke/poke-3.2.ebuild | 126 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 127 insertions(+)

diff --git a/dev-util/poke/Manifest b/dev-util/poke/Manifest
index 5e153dbaec48..9f2c77817bd0 100644
--- a/dev-util/poke/Manifest
+++ b/dev-util/poke/Manifest
@@ -2,3 +2,4 @@ DIST poke-2.4.tar.gz 7372092 BLAKE2B 64b8b22713bb581c30b624200c0a283a8de548895db
 DIST poke-2.90.1.tar.gz 7512925 BLAKE2B 38c9283f1c0b183b1b74c2ebd347edf6e9a9191d19070f7da32e6b0f520ec8197be3a813bc98160b47363cd11069bdaf84bb528498fe51cf2dcadf0bfa06a25e SHA512 f5823bed61ab64c2cdde83c918716fe64ad5552499023b2f5202130d6b2bab405c9d1cb1e12c7f190749689d86bf36f4edfe140ce748ac4c5f03d219197558d3
 DIST poke-3.0.tar.gz 7510801 BLAKE2B 4e80bd0603b0f690f7b6dc9b3913bb165f61160cd6e677751e6f8ea444bc395141204cc32c3ed97bad4b4044d505a800a64a4c973200e7338b50f05d9ea90c25 SHA512 5b786cdfae732a1f7196b0c4bf271c97f204f8fe9de9b34d92704f35150c8abfc2c080940d67efac63e3e82d0d4afe2fde4b75066faf9f4d1e9df6b6f62edb96
 DIST poke-3.1.tar.gz 7562582 BLAKE2B c348973185e7f33d670a9dccab60c02e8ccc247c5aa46936ac4b04674687c9e7edae707639a16c3853232b422d0c969930fe3879b59c1dba351fe7c3da56d34f SHA512 5680ce13b0a8e9a1f2770d295bccf7ccbe3aff54f3f4301a12c4719f54a6717ce5addb6ae3fe0478d0e426ccc756ef06a5e852b0d6ada0f8d3c587640ad209dd
+DIST poke-3.2.tar.gz 7559660 BLAKE2B c1d5739a1a497fb3daadec53fe812b65ec787dd268030a6517764541497c82451f4df391f3c434ef7729bc8e3762c31852ef3ce41aa83928e7646c40bde557dd SHA512 bd3651a2962165b318cc59c53604199eb6278ee3be45c18c36864612b0926d78a06f0e1338fdcc1fcd1cd48e2792bb3cd36a2bb5383143a66dc3aab023c0019c

diff --git a/dev-util/poke/poke-3.2.ebuild b/dev-util/poke/poke-3.2.ebuild
new file mode 100644
index 000000000000..80e149428e9b
--- /dev/null
+++ b/dev-util/poke/poke-3.2.ebuild
@@ -0,0 +1,126 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp-common flag-o-matic toolchain-funcs
+
+DESCRIPTION="Extensible editor for structured binary data"
+HOMEPAGE="https://www.jemarch.net/poke"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.savannah.gnu.org/git/poke.git"
+	REGEN_BDEPEND="
+		>=sys-devel/autoconf-2.62
+		>=sys-devel/automake-1.16
+		sys-apps/gawk
+		sys-apps/help2man
+		sys-apps/texinfo
+		sys-devel/bison
+		sys-devel/flex
+	"
+elif [[ $(ver_cut 2) -ge 90 || $(ver_cut 3) -ge 90 ]]; then
+	SRC_URI="https://alpha.gnu.org/gnu/poke/${P}.tar.gz"
+	REGEN_BDEPEND=""
+else
+	SRC_URI="mirror://gnu/poke/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	REGEN_BDEPEND=""
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="emacs pvm-profiling nbd nls test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/boehm-gc:=
+	dev-libs/libatomic_ops
+	sys-devel/gettext
+	sys-libs/readline:=
+	emacs? ( >=app-editors/emacs-23.1:* )
+	nbd? ( sys-libs/libnbd )
+"
+DEPEND="
+	${RDEPEND}
+	test? ( nbd? ( sys-libs/libnbd[uri-support] ) )
+"
+BDEPEND="
+	${REGEN_BDEPEND}
+	virtual/pkgconfig
+	pvm-profiling? ( sys-devel/gcc )
+	emacs? ( >=app-editors/emacs-23.1:* )
+	test? (
+		dev-util/dejagnu
+		nbd? ( sys-block/nbdkit )
+	)
+"
+
+SITEFILE="50${PN}-gentoo.el"
+
+pkg_pretend() {
+	if use pvm-profiling && ! tc-is-gcc; then
+		die "USE=pvm-profiling requires GCC"
+	fi
+}
+
+pkg_setup() {
+	use emacs && elisp-check-emacs-version
+}
+
+src_prepare() {
+	default
+
+	if [[ ${PV} == 9999 ]]; then
+		./bootstrap || die
+	fi
+}
+
+src_configure() {
+	# See bug 858461.
+	# Upstream support might happen one day.  For context, only one file needs
+	# LTO to be disabled (since it's an autogenerated bytecode interpreter),
+	# others do not.  The build system will handle this at some point in the
+	# future.  Until then, just filter out LTO.
+	filter-lto
+
+	local myconf=(
+		--with-lispdir="${EPREFIX}/${SITELISP}/${PN}"
+		--enable-hserver
+		$(use_enable nbd libnbd)
+		$(use_enable pvm-profiling)
+		$(use_enable nls)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_compile() {
+	default
+
+	if use emacs; then
+		cd etc || die
+		elisp-compile *.el
+	fi
+}
+
+src_install() {
+	default
+
+	if use emacs; then
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+		cd etc || die
+		elisp-install "${PN}" *.el *.elc
+	fi
+	find "${ED}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}

next             reply	other threads:[~2023-05-14  9:33 UTC|newest]

Thread overview: 47+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2023-05-14  9:32 Arsen Arsenović [this message]
  -- strict thread matches above, loose matches on Subject: below --
2025-03-12 14:06 [gentoo-commits] repo/gentoo:master commit in: dev-util/poke/ Arsen Arsenović
2025-01-07 22:44 Sam James
2024-06-14 14:42 Arthur Zamarin
2024-06-14 13:36 Arsen Arsenović
2024-04-02 11:55 Arsen Arsenović
2024-04-02 11:55 Arsen Arsenović
2024-02-11 13:23 Arsen Arsenović
2024-01-22 14:04 Arsen Arsenović
2024-01-20 15:56 Arsen Arsenović
2023-11-23 19:53 Sam James
2023-11-21 19:37 Arsen Arsenović
2023-08-20 16:31 Arsen Arsenović
2023-05-14 16:42 Arsen Arsenović
2023-04-18  0:22 Arsen Arsenović
2023-04-01 16:30 Arthur Zamarin
2023-01-25 21:10 Arsen Arsenović
2023-01-25  0:29 Arsen Arsenović
2023-01-25  0:29 Arsen Arsenović
2023-01-24 23:46 Arsen Arsenović
2023-01-24 23:46 Arsen Arsenović
2023-01-24 23:46 Arsen Arsenović
2023-01-21 18:00 Arsen Arsenović
2023-01-21 18:00 Arsen Arsenović
2022-12-05 19:00 Arthur Zamarin
2022-12-04 21:15 Sam James
2022-12-03 11:06 Sam James
2022-11-22  8:11 Sam James
2022-09-17 14:34 Sam James
2022-09-17 14:34 Sam James
2022-04-17 19:00 Sam James
2022-04-10 15:12 Florian Schmaus
2022-04-10 15:12 Florian Schmaus
2022-04-10 15:12 Florian Schmaus
2022-02-23  4:05 Sam James
2022-02-23  4:05 Sam James
2021-07-30  8:55 Sergei Trofimovich
2021-06-12 10:07 Sergei Trofimovich
2021-06-06  9:20 Sergei Trofimovich
2021-04-24 12:37 Sergei Trofimovich
2021-04-19 23:41 Sergei Trofimovich
2021-04-02  9:54 Sergei Trofimovich
2021-03-27 22:18 Sergei Trofimovich
2021-03-25 20:31 Sergei Trofimovich
2021-02-26 22:38 Sergei Trofimovich
2021-02-26 22:01 Sergei Trofimovich
2021-02-26 19:59 Sergei Trofimovich

find likely ancestor, descendant, or conflicting patches for this message:
( dfblob:5e153dbaec4 dfblob:9f2c77817bd dfblob:80e149428e9 )
 OR (
bs:"[gentoo-commits] repo/gentoo:master commit in: dev-util/poke/" )
	(help)

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=1684056749.6c8a26a3043640120b737951648b2b053fd3eca7.arsen@gentoo \
    --to=arsen@gentoo.org \
    --cc=gentoo-commits@lists.gentoo.org \
    --cc=gentoo-dev@lists.gentoo.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link

Be sure your reply has a Subject: header at the top and a blank line before the message body.

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox