[gentoo-commits] repo/gentoo:master commit in: dev-libs/apache-arrow/

public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed

From: "Alfredo Tupone" <tupone@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-libs/apache-arrow/
Date: Fri,  5 May 2023 19:25:53 +0000 (UTC)	[thread overview]
Message-ID: <1683314693.567099e23e11fcb8fe6c9620bb8da3e2ead16c04.tupone@gentoo> (raw)

commit:     567099e23e11fcb8fe6c9620bb8da3e2ead16c04
Author:     Alfredo Tupone <tupone <AT> gentoo <DOT> org>
AuthorDate: Fri May  5 19:16:53 2023 +0000
Commit:     Alfredo Tupone <tupone <AT> gentoo <DOT> org>
CommitDate: Fri May  5 19:24:53 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=567099e2

dev-libs/apache-arrow: add 12.0.0

Signed-off-by: Alfredo Tupone <tupone <AT> gentoo.org>

 dev-libs/apache-arrow/Manifest                   |   3 +
 dev-libs/apache-arrow/apache-arrow-12.0.0.ebuild | 120 +++++++++++++++++++++++
 2 files changed, 123 insertions(+)

diff --git a/dev-libs/apache-arrow/Manifest b/dev-libs/apache-arrow/Manifest
index 42267587e393..62bc5186864f 100644
--- a/dev-libs/apache-arrow/Manifest
+++ b/dev-libs/apache-arrow/Manifest
@@ -1,3 +1,6 @@
 DIST apache-arrow-11.0.0.tar.gz 19956186 BLAKE2B dff0faecbde9e2d19f092fd0c48a7ac7a401da6dbfd17f30af1b35c9e3fd3e1ba5611311f5bcb08383368de195cff783a178a9397a63a1c4f740a81349f8b8d3 SHA512 46df4fb5a703d38d0a74fde9838e9f9702b24b442cb225517516c335a5ab18955699000bf0b2fc7d1698ada6d2e890ba3860933b6280f5160b0fce8a07484d0e
+DIST apache-arrow-12.0.0.tar.gz 20159048 BLAKE2B 43b4f36e1d1f84fc83c46a3627ad72cead38310f4325b8d21d17d726cd416016f0839d312c80737c0a921da6aefee537413e30309a656301c19834c2986d734e SHA512 f815be4fb20b6001ba5525270765fe239b5468708a7be34b93b60ee0ce63464727d183c9756fbc33bffd199019e1f06a7fddd306ce8388435cea7771070a2ca9
 DIST apache-arrow-arrow-data-11.0.0.tar.gz 3570422 BLAKE2B df1f8d1c4e321ca0abdce598b09945aa9e63114199e7f2eb0fc549323dadf703b917efd90c04a2d540d763a44128d76c6ee12788a983d4b9536d04297316b656 SHA512 0be19960b0d22fc2e07bf84f11148e69d6fa82f10627eb2a5e4b762b1d4cf4e151a57c5a1dc761d6d8ed29881ea589e4cfe0cd47d5c7cbf7b6107143b4a45e82
+DIST apache-arrow-arrow-data-12.0.0.tar.gz 3570422 BLAKE2B df1f8d1c4e321ca0abdce598b09945aa9e63114199e7f2eb0fc549323dadf703b917efd90c04a2d540d763a44128d76c6ee12788a983d4b9536d04297316b656 SHA512 0be19960b0d22fc2e07bf84f11148e69d6fa82f10627eb2a5e4b762b1d4cf4e151a57c5a1dc761d6d8ed29881ea589e4cfe0cd47d5c7cbf7b6107143b4a45e82
 DIST apache-arrow-parquet-data-11.0.0.tar.gz 1013835 BLAKE2B cb4e544b6588ddad503f9692ee2eee5d4f1e931f10654b7253e11ffd2feb4c957dec047a1b1644c1f1538a3bf7ea726e5a9ae9b7d0c3bb0d55d27f088b5c5be3 SHA512 d4c2af20d6a88c1beb44770982f4aa324ea4ee375e8f556339074875af15c48f4398d972c1eec35eba5d209e9e62df4bdbf73ebc8148a7bb05ffa2d69c97df61
+DIST apache-arrow-parquet-data-12.0.0.tar.gz 1013835 BLAKE2B cb4e544b6588ddad503f9692ee2eee5d4f1e931f10654b7253e11ffd2feb4c957dec047a1b1644c1f1538a3bf7ea726e5a9ae9b7d0c3bb0d55d27f088b5c5be3 SHA512 d4c2af20d6a88c1beb44770982f4aa324ea4ee375e8f556339074875af15c48f4398d972c1eec35eba5d209e9e62df4bdbf73ebc8148a7bb05ffa2d69c97df61

diff --git a/dev-libs/apache-arrow/apache-arrow-12.0.0.ebuild b/dev-libs/apache-arrow/apache-arrow-12.0.0.ebuild
new file mode 100644
index 000000000000..148ff46363d1
--- /dev/null
+++ b/dev-libs/apache-arrow/apache-arrow-12.0.0.ebuild
@@ -0,0 +1,120 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+ARROW_DATA_GIT_HASH=d2c73bf78246331d8e58b6f11aa8aa199cbb5929
+PARQUET_DATA_GIT_HASH=b2e7cc755159196e3a068c8594f7acbaecfdaaac
+
+DESCRIPTION="A cross-language development platform for in-memory data."
+HOMEPAGE="https://arrow.apache.org/"
+SRC_URI="
+	mirror://apache/arrow/arrow-${PV}/${P}.tar.gz
+	test? (
+		https://github.com/apache/parquet-testing/archive/${PARQUET_DATA_GIT_HASH}.tar.gz
+			-> ${PN}-parquet-data-${PV}.tar.gz
+		https://github.com/apache/arrow-testing/archive/${ARROW_DATA_GIT_HASH}.tar.gz
+			-> ${PN}-arrow-data-${PV}.tar.gz
+	)
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="brotli bzip2 compute dataset +json lz4 parquet re2 snappy ssl test zlib zstd"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	brotli? ( app-arch/brotli )
+	bzip2? ( app-arch/bzip2 )
+	compute? ( dev-libs/libutf8proc )
+	dataset? (
+		dev-libs/libutf8proc
+		re2? ( dev-libs/re2 )
+	)
+	lz4? ( app-arch/lz4 )
+	parquet? (
+		dev-libs/libutf8proc
+		dev-libs/thrift
+		ssl? ( dev-libs/openssl )
+	)
+	snappy? ( app-arch/snappy )
+	zlib? ( sys-libs/zlib )
+	zstd? ( app-arch/zstd )
+"
+DEPEND="${RDEPEND}
+	dev-cpp/xsimd
+	json? ( dev-libs/rapidjson )
+	test? (
+		dev-libs/boost
+		dev-cpp/gflags
+		dev-cpp/gtest
+	)
+"
+
+REQUIRED_USE="test? (
+		json
+		parquet? ( zstd )
+	)
+	ssl? ( json )"
+
+S="${WORKDIR}/${P}/cpp"
+
+PATCHES=( "${FILESDIR}/${PN}-11.0.0-shared-lz4.patch" )
+
+src_prepare() {
+	# use Gentoo CXXFLAGS, specify docdir at src_configure.
+	sed -i \
+		-e '/SetupCxxFlags/d' \
+		-e '/set(ARROW_DOC_DIR.*)/d' \
+		CMakeLists.txt \
+		|| die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DARROW_BUILD_STATIC=OFF
+		-DARROW_BUILD_TESTS=$(usex test)
+		-DARROW_COMPUTE=$(usex compute)
+		-DARROW_CSV=ON
+		-DARROW_DATASET=$(usex dataset)
+		-DARROW_DEPENDENCY_SOURCE=SYSTEM
+		-DARROW_DOC_DIR=share/doc/${PF}
+		-DARROW_FILESYSTEM=ON
+		-DARROW_HDFS=ON
+		-DARROW_JEMALLOC=OFF
+		-DARROW_JSON=$(usex json)
+		-DARROW_PARQUET=$(usex parquet)
+		-DPARQUET_REQUIRE_ENCRYPTION=$(usex ssl)
+		-DARROW_USE_CCACHE=OFF
+		-DARROW_USE_SCCACHE=OFF
+		-DARROW_WITH_BROTLI=$(usex brotli)
+		-DARROW_WITH_BZ2=$(usex bzip2)
+		-DARROW_WITH_LZ4=$(usex lz4)
+		-DARROW_WITH_RE2=$(usex re2)
+		-DARROW_WITH_SNAPPY=$(usex snappy)
+		-DARROW_WITH_ZLIB=$(usex zlib)
+		-DARROW_WITH_ZSTD=$(usex zstd)
+		-DCMAKE_CXX_STANDARD=17
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	export PARQUET_TEST_DATA="${WORKDIR}/parquet-testing-${PARQUET_DATA_GIT_HASH}/data"
+	export ARROW_TEST_DATA="${WORKDIR}/arrow-testing-${ARROW_DATA_GIT_HASH}/data"
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+	if use test; then
+		cd "${D}"/usr/$(get_libdir)
+		rm -r cmake/ArrowTesting || die
+		rm libarrow_testing* || die
+		rm pkgconfig/arrow-testing.pc || die
+	fi
+}

next             reply	other threads:[~2023-05-05 19:25 UTC|newest]

Thread overview: 66+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2023-05-05 19:25 Alfredo Tupone [this message]
  -- strict thread matches above, loose matches on Subject: below --
2025-09-08 14:42 [gentoo-commits] repo/gentoo:master commit in: dev-libs/apache-arrow/ Michał Górny
2025-08-02 16:30 Sam James
2025-08-02 15:11 Arthur Zamarin
2025-08-02  6:15 Michał Górny
2025-07-18  4:39 Michał Górny
2025-05-21  5:38 Michał Górny
2025-05-18 11:06 Sam James
2025-05-17 17:41 Arthur Zamarin
2025-04-29  9:52 Michał Górny
2025-04-28  3:16 Michał Górny
2025-03-08 19:29 Michał Górny
2025-03-08 16:56 Sam James
2025-03-08 14:15 Arthur Zamarin
2025-03-08 13:15 Arthur Zamarin
2025-02-19  7:56 Michał Górny
2025-02-09 12:57 Michał Górny
2025-02-08 19:07 Sam James
2025-02-08 19:07 Sam James
2025-02-08 13:55 Arthur Zamarin
2025-01-17  4:33 Michał Górny
2024-12-20 21:11 Alfredo Tupone
2024-12-16  6:11 Michał Górny
2024-12-14 12:37 Sam James
2024-12-14 10:58 Arthur Zamarin
2024-11-26  7:01 Michał Górny
2024-11-16  9:00 Arthur Zamarin
2024-11-16  8:19 Michał Górny
2024-11-16  8:09 Michał Górny
2024-11-13  1:57 Sam James
2024-11-13  1:57 Sam James
2024-10-28 18:15 Michał Górny
2024-08-05  1:56 Sam James
2024-07-17 12:35 Michał Górny
2024-06-03  1:52 Michał Górny
2024-06-01 11:32 Arthur Zamarin
2024-05-15  1:40 Michał Górny
2024-05-08  7:50 Michał Górny
2024-04-21  2:35 Michał Górny
2024-04-21  2:35 Michał Górny
2024-04-13  6:26 Arthur Zamarin
2024-03-30 15:28 Michał Górny
2024-03-29  9:44 Arthur Zamarin
2024-03-22 20:23 Arthur Zamarin
2024-03-22 20:23 Arthur Zamarin
2024-03-19 20:09 Michał Górny
2024-03-13 20:48 Michał Górny
2024-03-13 15:03 Arthur Zamarin
2024-02-02 16:05 Michał Górny
2024-02-02 16:05 Michał Górny
2024-01-23 22:59 Jakov Smolić
2024-01-23 17:30 Arthur Zamarin
2024-01-20 16:00 Alfredo Tupone
2023-12-28 21:13 Alfredo Tupone
2023-12-27 22:18 Alfredo Tupone
2023-12-25 22:49 Alfredo Tupone
2023-11-21 15:02 Alfredo Tupone
2023-10-26 17:00 Michał Górny
2023-10-14  7:43 Alfredo Tupone
2023-07-09 19:31 Alfredo Tupone
2023-05-14 15:49 Alfredo Tupone
2023-05-10 17:04 Alfredo Tupone
2023-04-23 17:52 Alfredo Tupone
2023-04-23 15:45 Alfredo Tupone
2023-04-23 13:20 Alfredo Tupone
2023-04-23  6:42 Alfredo Tupone

find likely ancestor, descendant, or conflicting patches for this message:
( dfblob:42267587e39 dfblob:62bc5186864 dfblob:148ff46363d )
 OR (
bs:"[gentoo-commits] repo/gentoo:master commit in: dev-libs/apache-arrow/" )
	(help)

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=1683314693.567099e23e11fcb8fe6c9620bb8da3e2ead16c04.tupone@gentoo \
    --to=tupone@gentoo.org \
    --cc=gentoo-commits@lists.gentoo.org \
    --cc=gentoo-dev@lists.gentoo.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link

Be sure your reply has a Subject: header at the top and a blank line before the message body.

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox