From: "Viorel Munteanu" <ceamac@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: net-dialup/minicom/
Date: Sun, 19 Mar 2023 06:51:16 +0000 (UTC) [thread overview]
Message-ID: <1679208573.d7aa4284f78b05a1f504631aedf95a95c2c8fc7f.ceamac@gentoo> (raw)
commit: d7aa4284f78b05a1f504631aedf95a95c2c8fc7f
Author: Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 19 06:27:24 2023 +0000
Commit: Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
CommitDate: Sun Mar 19 06:49:33 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d7aa4284
net-dialup/minicom: update EAPI 7 -> 8
Remove weird /etc/minicom/minirc.dfl logic.
Closes: https://bugs.gentoo.org/885709
Closes: https://github.com/gentoo/gentoo/pull/30228
Signed-off-by: Viorel Munteanu <ceamac <AT> gentoo.org>
net-dialup/minicom/minicom-2.8-r2.ebuild | 60 ++++++++++++++++++++++++++++++++
1 file changed, 60 insertions(+)
diff --git a/net-dialup/minicom/minicom-2.8-r2.ebuild b/net-dialup/minicom/minicom-2.8-r2.ebuild
new file mode 100644
index 000000000000..6a31287bdcb2
--- /dev/null
+++ b/net-dialup/minicom/minicom-2.8-r2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Serial Communication Program"
+HOMEPAGE="https://salsa.debian.org/minicom-team/minicom"
+SRC_URI="https://salsa.debian.org/${PN}-team/${PN}/-/archive/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="nls"
+
+DEPEND="sys-libs/ncurses:="
+
+RDEPEND="
+ ${DEPEND}
+ net-dialup/lrzsz
+"
+
+BDEPEND="
+ virtual/pkgconfig
+ nls? ( sys-devel/gettext )
+"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-2.8-gentoo-runscript.patch
+ "${FILESDIR}"/${PN}-2.8-lockdir.patch
+)
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+src_configure() {
+ # Lockdir must exist if not manually specified.
+ # '/var/lock' is created by OpenRC.
+ local myeconfargs=(
+ # See bug #788142
+ --sysconfdir="${EPREFIX}"/etc/${PN}
+
+ --disable-rpath
+ --enable-lock-dir="/var/lock"
+ $(use_enable nls)
+ )
+
+ econf "${myeconfargs[@]}"
+}
+
+src_install() {
+ default
+
+ # Needs to match --sysconfdir above
+ insinto /etc/minicom
+ doins "${FILESDIR}"/minirc.dfl
+}
next reply other threads:[~2023-03-19 6:51 UTC|newest]
Thread overview: 55+ messages / expand[flat|nested] mbox.gz Atom feed top
2023-03-19 6:51 Viorel Munteanu [this message]
-- strict thread matches above, loose matches on Subject: below --
2025-04-03 20:57 [gentoo-commits] repo/gentoo:master commit in: net-dialup/minicom/ Sam James
2025-04-03 20:40 Sam James
2025-04-03 20:40 Sam James
2025-04-03 19:24 Arthur Zamarin
2025-04-03 19:24 Arthur Zamarin
2025-04-03 19:24 Arthur Zamarin
2025-04-03 16:52 Arthur Zamarin
2025-02-23 8:58 Viorel Munteanu
2025-02-23 8:58 Viorel Munteanu
2023-11-29 13:45 Arthur Zamarin
2023-11-29 13:18 Arthur Zamarin
2023-11-29 11:45 Arthur Zamarin
2023-11-26 12:38 Arthur Zamarin
2023-11-26 12:38 Arthur Zamarin
2023-11-26 12:38 Arthur Zamarin
2023-11-26 12:38 Arthur Zamarin
2023-08-25 7:49 Viorel Munteanu
2023-08-20 6:24 Viorel Munteanu
2023-04-19 11:14 Viorel Munteanu
2023-04-19 11:07 Sam James
2023-04-19 10:16 Arthur Zamarin
2023-04-19 9:46 Sam James
2023-04-19 9:45 Sam James
2023-04-19 9:45 Sam James
2023-04-19 9:45 Sam James
2023-04-19 9:43 Sam James
2023-03-02 16:49 Arthur Zamarin
2023-03-02 16:49 Arthur Zamarin
2023-03-02 16:48 Arthur Zamarin
2023-03-01 17:57 Arthur Zamarin
2023-03-01 17:33 Arthur Zamarin
2023-03-01 17:33 Arthur Zamarin
2023-03-01 16:36 Arthur Zamarin
2022-01-17 5:48 Sam James
2021-09-27 16:36 Marek Szuba
2021-05-04 19:13 Sam James
2021-05-01 14:06 Sam James
2021-04-30 23:39 Sam James
2021-04-30 23:37 Sam James
2021-04-30 23:29 Sam James
2021-04-30 20:28 Sergei Trofimovich
2021-04-30 15:23 Agostino Sarubbo
2020-01-19 12:58 Sergei Trofimovich
2018-01-05 22:02 Ulrich Müller
2017-10-12 17:01 Tim Harder
2017-10-12 17:01 Tim Harder
2017-10-12 17:01 Tim Harder
2017-05-04 20:03 Markus Meier
2017-04-30 9:37 Agostino Sarubbo
2017-04-24 12:44 Tobias Klausmann
2017-04-22 13:19 Jeroen Roovers
2017-04-18 17:20 Robin H. Johnson
2017-01-29 19:33 Fabian Groffen
2016-01-22 8:28 Michael Palimaka
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1679208573.d7aa4284f78b05a1f504631aedf95a95c2c8fc7f.ceamac@gentoo \
--to=ceamac@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox