[gentoo-commits] repo/gentoo:master commit in: app-containers/lxd/

public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed

From: "Joonas Niilola" <juippis@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: app-containers/lxd/
Date: Sun, 22 Jan 2023 07:24:41 +0000 (UTC)	[thread overview]
Message-ID: <1674372278.89e2e41d3bdf383fece4fd8d20bb7534d16346e6.juippis@gentoo> (raw)

commit:     89e2e41d3bdf383fece4fd8d20bb7534d16346e6
Author:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 22 07:20:51 2023 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Sun Jan 22 07:24:38 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=89e2e41d

app-containers/lxd: clean old

Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 app-containers/lxd/lxd-5.0.1-r2.ebuild | 190 ---------------------------------
 1 file changed, 190 deletions(-)

diff --git a/app-containers/lxd/lxd-5.0.1-r2.ebuild b/app-containers/lxd/lxd-5.0.1-r2.ebuild
deleted file mode 100644
index 6ef72f36e908..000000000000
--- a/app-containers/lxd/lxd-5.0.1-r2.ebuild
+++ /dev/null
@@ -1,190 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit bash-completion-r1 go-module linux-info optfeature systemd verify-sig
-
-DESCRIPTION="Modern, secure and powerful system container and virtual machine manager"
-HOMEPAGE="https://linuxcontainers.org/lxd/introduction/ https://github.com/lxc/lxd"
-SRC_URI="https://linuxcontainers.org/downloads/lxd/${P}.tar.gz
-	verify-sig? ( https://linuxcontainers.org/downloads/lxd/${P}.tar.gz.asc )"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="amd64 ~arm64 ~x86"
-IUSE="apparmor ipv6 nls verify-sig"
-
-DEPEND="acct-group/lxd
-	app-arch/xz-utils
-	>=app-containers/lxc-3.0.0[apparmor?,seccomp(+)]
-	dev-db/sqlite:3
-	dev-libs/dqlite:=
-	dev-libs/lzo
-	dev-libs/raft[lz4]
-	>=dev-util/xdelta-3.0[lzma(+)]
-	net-dns/dnsmasq[dhcp,ipv6(+)?]
-	sys-libs/libcap
-	virtual/udev"
-RDEPEND="${DEPEND}
-	net-firewall/ebtables
-	net-firewall/iptables[ipv6(+)?]
-	sys-apps/iproute2[ipv6(+)?]
-	sys-fs/fuse:*
-	>=sys-fs/lxcfs-5.0.0
-	sys-fs/squashfs-tools[lzma]
-	virtual/acl"
-BDEPEND="dev-lang/go
-	nls? ( sys-devel/gettext )
-	verify-sig? ( sec-keys/openpgp-keys-linuxcontainers )"
-
-CONFIG_CHECK="
-	~CGROUPS
-	~IPC_NS
-	~NET_NS
-	~PID_NS
-
-	~SECCOMP
-	~USER_NS
-	~UTS_NS
-
-	~KVM
-	~MACVTAP
-	~VHOST_VSOCK
-"
-
-ERROR_IPC_NS="CONFIG_IPC_NS is required."
-ERROR_NET_NS="CONFIG_NET_NS is required."
-ERROR_PID_NS="CONFIG_PID_NS is required."
-ERROR_SECCOMP="CONFIG_SECCOMP is required."
-ERROR_UTS_NS="CONFIG_UTS_NS is required."
-
-WARNING_KVM="CONFIG_KVM and CONFIG_KVM_AMD/-INTEL is required for virtual machines."
-WARNING_MACVTAP="CONFIG_MACVTAP is required for virtual machines."
-WARNING_VHOST_VSOCK="CONFIG_VHOST_VSOCK is required for virtual machines."
-
-# Go magic.
-QA_PREBUILT="/usr/bin/fuidshift
-	/usr/bin/lxc
-	/usr/bin/lxc-to-lxd
-	/usr/bin/lxd-agent
-	/usr/bin/lxd-benchmark
-	/usr/bin/lxd-migrate
-	/usr/sbin/lxd"
-
-VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/linuxcontainers.asc
-
-# The testsuite must be run as root.
-# make: *** [Makefile:156: check] Error 1
-RESTRICT="test"
-
-GOPATH="${S}/_dist"
-
-src_prepare() {
-	export GOPATH="${S}/_dist"
-
-	default
-
-	sed -i \
-		-e "s:\./configure:./configure --prefix=/usr --libdir=${EPREFIX}/usr/lib/lxd:g" \
-		-e "s:make:make ${MAKEOPTS}:g" \
-		Makefile || die
-
-	# Fix hardcoded ovmf file path, see bug 763180
-	sed -i \
-		-e "s:/usr/share/OVMF:/usr/share/edk2-ovmf:g" \
-		-e "s:OVMF_VARS.ms.fd:OVMF_VARS.fd:g" \
-		doc/environment.md \
-		lxd/apparmor/instance.go \
-		lxd/apparmor/instance_qemu.go \
-		lxd/instance/drivers/driver_qemu.go || die "Failed to fix hardcoded ovmf paths."
-
-	# Fix hardcoded virtfs-proxy-helper file path, see bug 798924
-	sed -i \
-		-e "s:/usr/lib/qemu/virtfs-proxy-helper:/usr/libexec/virtfs-proxy-helper:g" \
-		lxd/device/device_utils_disk.go || die "Failed to fix virtfs-proxy-helper path."
-
-	cp "${FILESDIR}"/lxd-4.0.9-r1.service "${T}"/lxd.service || die
-	if use apparmor; then
-		sed -i \
-			'/^EnvironmentFile=.*/a ExecStartPre=\/usr\/libexec\/lxc\/lxc-apparmor-load' \
-			"${T}"/lxd.service || die
-	fi
-
-	# Disable -Werror's from go modules.
-	find "${S}" -name "cgo.go" -exec sed -i "s/ -Werror / /g" {} + || die
-}
-
-src_configure() { :; }
-
-src_compile() {
-	export GOPATH="${S}/_dist"
-	export CGO_LDFLAGS_ALLOW="-Wl,-z,now"
-
-	for k in fuidshift lxd-benchmark lxc lxc-to-lxd; do
-		go install -v -x "${S}/${k}" || die "failed compiling ${k}"
-	done
-
-	go install -v -x -tags libsqlite3 "${S}"/lxd || die "Failed to build the daemon"
-
-	# Needs to be built statically
-	CGO_ENABLED=0 go install -v -tags netgo "${S}"/lxd-migrate
-	CGO_ENABLED=0 go install -v -tags agent,netgo "${S}"/lxd-agent
-
-	use nls && emake build-mo
-}
-
-src_test() {
-	emake check
-}
-
-src_install() {
-	export GOPATH="${S}/_dist"
-	local bindir="_dist/bin"
-
-	dosbin ${bindir}/lxd
-
-	for l in fuidshift lxd-agent lxd-benchmark lxd-migrate lxc lxc-to-lxd; do
-		dobin ${bindir}/${l}
-	done
-
-	newbashcomp scripts/bash/lxd-client lxc
-
-	newconfd "${FILESDIR}"/lxd-4.0.0.confd lxd
-	newinitd "${FILESDIR}"/lxd-4.0.9.initd lxd
-
-	systemd_dounit "${T}"/lxd.service
-	systemd_newunit "${FILESDIR}"/lxd-containers-4.0.0.service lxd-containers.service
-	systemd_newunit "${FILESDIR}"/lxd-4.0.0.socket lxd.socket
-
-	dodoc AUTHORS
-	dodoc -r doc/*
-	use nls && domo po/*.mo
-}
-
-pkg_postinst() {
-	elog
-	elog "Consult https://wiki.gentoo.org/wiki/LXD for more information,"
-	elog "including a Quick Start."
-	elog "For virtual machine support, see:"
-	elog "https://wiki.gentoo.org/wiki/LXD#Virtual_machines"
-	elog
-	elog "Please run 'lxc-checkconfig' to see all optional kernel features."
-	elog
-	optfeature "virtual machine support" app-emulation/qemu[spice,usbredir,virtfs]
-	optfeature "btrfs storage backend" sys-fs/btrfs-progs
-	optfeature "lvm2 storage backend" sys-fs/lvm2
-	optfeature "zfs storage backend" sys-fs/zfs
-	elog
-	elog "Be sure to add your local user to the lxd group."
-
-	if [[ -n ${REPLACING_VERSIONS} ]] && has_version app-emulation/qemu[spice,usbredir,virtfs]; then
-		ewarn ""
-		ewarn "You're updating from <5.0.1. Due to incompatible API updates in the lxd-agent"
-		ewarn "product, you'll have to restart any running virtual machines before they work"
-		ewarn "properly."
-		ewarn ""
-		ewarn "Run: 'lxc restart your-vm' after the update for your vm's managed by lxd."
-		ewarn ""
-	fi
-}

next             reply	other threads:[~2023-01-22  7:24 UTC|newest]

Thread overview: 55+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2023-01-22  7:24 Joonas Niilola [this message]
  -- strict thread matches above, loose matches on Subject: below --
2025-09-02 13:10 [gentoo-commits] repo/gentoo:master commit in: app-containers/lxd/ Joonas Niilola
2025-09-02 13:10 Joonas Niilola
2025-09-02 13:10 Joonas Niilola
2025-09-02 13:10 Joonas Niilola
2025-03-31 12:58 Joonas Niilola
2025-03-31 12:58 Joonas Niilola
2025-03-31 12:58 Joonas Niilola
2024-10-10 16:33 James Le Cuirot
2024-07-11 16:40 Joonas Niilola
2024-07-11 16:36 Joonas Niilola
2024-07-08  7:17 Joonas Niilola
2024-06-01  8:37 Joonas Niilola
2024-06-01  8:37 Joonas Niilola
2024-05-13 18:27 Joonas Niilola
2024-04-22  6:28 Joonas Niilola
2024-02-29  7:29 Joonas Niilola
2024-02-27  7:28 Joonas Niilola
2024-02-25  9:36 Joonas Niilola
2024-02-25  9:36 Joonas Niilola
2024-02-25  9:36 Joonas Niilola
2024-02-25  9:36 Joonas Niilola
2023-12-12 19:50 Joonas Niilola
2023-12-12 18:05 Joonas Niilola
2023-12-12 16:55 Joonas Niilola
2023-10-19 16:06 Joonas Niilola
2023-10-19 16:06 Joonas Niilola
2023-10-16 13:22 Joonas Niilola
2023-09-22  8:42 Joonas Niilola
2023-09-10 13:23 Joonas Niilola
2023-07-05  6:12 Joonas Niilola
2023-06-15 12:14 Joonas Niilola
2023-03-25  6:32 Joonas Niilola
2023-03-09  6:50 Joonas Niilola
2023-02-22  7:14 Joonas Niilola
2023-02-22  6:25 Joonas Niilola
2023-01-22 17:21 Joonas Niilola
2023-01-22  7:24 Joonas Niilola
2023-01-10 14:03 Joonas Niilola
2023-01-10 13:25 Joonas Niilola
2022-11-19  7:37 Joonas Niilola
2022-11-14  7:44 Joonas Niilola
2022-11-12  6:23 Joonas Niilola
2022-10-12 16:40 Joonas Niilola
2022-09-24 13:57 Joonas Niilola
2022-09-19  6:06 Joonas Niilola
2022-08-19  8:45 Joonas Niilola
2022-08-17  6:18 Joonas Niilola
2022-07-18  7:01 Joonas Niilola
2022-06-14 14:35 Joonas Niilola
2022-06-11  9:17 Joonas Niilola
2022-05-22  8:13 Jakov Smolić
2022-03-21  9:31 Joonas Niilola
2022-03-20  6:22 Joonas Niilola
2022-01-07 13:39 Joonas Niilola

find likely ancestor, descendant, or conflicting patches for this message:
( dfblob:6ef72f36e90 )
 OR (
bs:"[gentoo-commits] repo/gentoo:master commit in: app-containers/lxd/" )
	(help)

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=1674372278.89e2e41d3bdf383fece4fd8d20bb7534d16346e6.juippis@gentoo \
    --to=juippis@gentoo.org \
    --cc=gentoo-commits@lists.gentoo.org \
    --cc=gentoo-dev@lists.gentoo.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link

Be sure your reply has a Subject: header at the top and a blank line before the message body.

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox