[gentoo-commits] repo/gentoo:master commit in: media-video/qmplay2/

public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed

From: "Arthur Zamarin" <arthurzam@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: media-video/qmplay2/
Date: Fri, 17 Jun 2022 06:20:54 +0000 (UTC)	[thread overview]
Message-ID: <1655446847.eec9911da50c564c92f42b4d067cf977533d2655.arthurzam@gentoo> (raw)

commit:     eec9911da50c564c92f42b4d067cf977533d2655
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Fri Jun 17 06:17:40 2022 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Fri Jun 17 06:20:47 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=eec9911d

media-video/qmplay2: add 22.06.16

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 media-video/qmplay2/Manifest                |   1 +
 media-video/qmplay2/qmplay2-22.06.16.ebuild | 137 ++++++++++++++++++++++++++++
 2 files changed, 138 insertions(+)

diff --git a/media-video/qmplay2/Manifest b/media-video/qmplay2/Manifest
index ed17f369d9ce..5b3fa80658e3 100644
--- a/media-video/qmplay2/Manifest
+++ b/media-video/qmplay2/Manifest
@@ -1,2 +1,3 @@
 DIST QMPlay2-src-21.12.24.tar.xz 1609604 BLAKE2B 0b2e1ddc0a089ee0d8d37d3d14f2273b53b4df078c6f1571a5ed44c1234133c3eb21461287eb12027ccb686d844f28939b8dfe236c11fd6cb5831dc825708301 SHA512 fddd1d28a0c7f8ad7fa8ef02bb1181ee2fe4babfd8b9c026d2b1d518c1cf28528c64d296b0050d7c51b1ae558baf2d04fe808b276816d98e839a85dbc67ac136
 DIST QMPlay2-src-22.03.19.tar.xz 1612136 BLAKE2B 5b5ff6d4b37c3d1c46e28839e078e3f7bfa4d2d9d88f552a574cc6560ee18996dda8649f47973f2af97224e2ebebbffadf3c6f52b8064fc30ff63c72d7f578e2 SHA512 687fa0b8bc7d3b99432419aeeaedc83773dc3b12d8133872f663419db7123e7093895bc8ac5b64f03acefd1c4e5cf916210ebbef6b6494284e15487763f0d571
+DIST QMPlay2-src-22.06.16.tar.xz 1613312 BLAKE2B b626b184f3d16c85dead8c61a5ccc0bb7b11e6a064fc6a3b4aedbd8a2e9631ac2182a00a5dd9c9de1feb5f357b45ce3d7dc66f9b46d88153cc3bce3d5f869a65 SHA512 f04a83422bcfa105b3ec33843962b844b6efed6700a26426f4a73c0588dc1179985d612748d5c74f6214fdcff86a035272473a35a54a234ec0abef388b0517fe

diff --git a/media-video/qmplay2/qmplay2-22.06.16.ebuild b/media-video/qmplay2/qmplay2-22.06.16.ebuild
new file mode 100644
index 000000000000..b7b2b595e0e7
--- /dev/null
+++ b/media-video/qmplay2/qmplay2-22.06.16.ebuild
@@ -0,0 +1,137 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="A Qt-based video player, which can play most formats and codecs"
+HOMEPAGE="https://github.com/zaps166/QMPlay2"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/zaps166/QMPlay2"
+else
+	SRC_URI="https://github.com/zaps166/QMPlay2/releases/download/${PV}/QMPlay2-src-${PV}.tar.xz"
+	S="${WORKDIR}/QMPlay2-src-${PV}"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="LGPL-3"
+SLOT="0"
+
+IUSE="avdevice +audiofilters +alsa cdio cuvid extensions gme inputs libass
+	modplug notifications opengl pipewire portaudio pulseaudio sid shaders
+	+taglib vaapi vdpau videofilters visualizations vulkan xv"
+
+REQUIRED_USE="
+	audiofilters? ( || ( alsa pipewire portaudio pulseaudio ) )
+	shaders? ( vulkan )"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-video/ffmpeg
+	|| (
+		dev-qt/qtgui:5[X(-)]
+		dev-qt/qtgui:5[xcb(-)]
+	)
+	alsa? ( media-libs/alsa-lib )
+	cdio? ( dev-libs/libcdio[cddb] )
+	extensions? ( dev-qt/qtdeclarative:5 )
+	gme? ( media-libs/game-music-emu )
+	libass? ( media-libs/libass )
+	opengl? ( virtual/opengl )
+	pipewire? ( media-video/pipewire )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-sound/pulseaudio )
+	sid? ( media-libs/libsidplayfp )
+	shaders? ( >=media-libs/shaderc-2020.1 )
+	taglib? ( media-libs/taglib	)
+	vaapi? (
+		>=media-video/ffmpeg-4.1.3[vaapi]
+		x11-libs/libva
+	)
+	vdpau? ( media-video/ffmpeg[vdpau] )
+	videofilters? ( dev-qt/qtconcurrent:5 )
+	vulkan? (
+		>=dev-qt/qtgui-5.14.1:5[vulkan]
+		>=media-libs/vulkan-loader-1.2.133
+	)
+	xv? ( x11-libs/libXv )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-qt/linguist-tools:5"
+
+src_prepare() {
+	# disable compress man pages
+	sed -r \
+		-e 's/if\(GZIP\)/if\(TRUE\)/' \
+		-e 's/(install.+QMPlay2\.1)\.gz/\1/' \
+		-i src/gui/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# core
+		-DUSE_LINK_TIME_OPTIMIZATION=false
+		-DUSE_UPDATES=OFF
+		-DUSE_ALSA=$(usex alsa)
+		-DUSE_AUDIOCD=$(usex cdio)
+		-DUSE_DBUS_SUSPEND=ON
+		-DUSE_FREEDESKTOP_NOTIFICATIONS=ON
+		-DUSE_LIBASS=$(usex libass)
+		-DUSE_NOTIFY=$(usex notifications)
+		-DUSE_OPENGL=$(usex opengl)
+		-DUSE_VULKAN=$(usex vulkan)
+		-DUSE_GLSLC=$(usex shaders)
+		-DUSE_XVIDEO=$(usex xv)
+
+		# ffmpeg
+		-DUSE_FFMPEG_AVDEVICE=$(usex avdevice)
+		-DUSE_FFMPEG_VAAPI=$(usex vaapi)
+		-DUSE_FFMPEG_VDPAU=$(usex vdpau)
+
+		# chiptune
+		-DUSE_CHIPTUNE_GME=$(usex gme)
+		-DUSE_CHIPTUNE_SID=$(usex sid)
+
+		# modules
+		-DUSE_AUDIOFILTERS=$(usex audiofilters)
+		-DUSE_CUVID=$(usex cuvid)
+		-DUSE_INPUTS=$(usex inputs)
+		-DUSE_MODPLUG=$(usex modplug)
+		-DUSE_PIPEWIRE=$(usex pipewire)
+		-DUSE_PORTAUDIO=$(usex portaudio)
+		-DUSE_PULSEAUDIO=$(usex pulseaudio)
+		-DUSE_TAGLIB=$(usex taglib)
+		-DUSE_VIDEOFILTERS=$(usex videofilters)
+		-DUSE_VISUALIZATIONS=$(usex visualizations)
+
+		# extensions
+		-DUSE_EXTENSIONS=$(usex extensions)
+	)
+
+	if use extensions; then
+		# Move inside an if, to remove unused option warning
+		mycmakeargs+=(
+			-DUSE_LASTFM=ON
+			-DUSE_LYRICS=ON
+			-DUSE_MEDIABROWSER=ON
+			-DUSE_MPRIS2=ON
+		)
+	fi
+
+	if [[ ${PV} == *9999 ]]; then
+		mycmakeargs+=( -DUSE_GIT_VERSION=true )
+	else
+		mycmakeargs+=( -DUSE_GIT_VERSION=false )
+	fi
+
+	cmake_src_configure
+}

next             reply	other threads:[~2022-06-17  6:20 UTC|newest]

Thread overview: 80+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2022-06-17  6:20 Arthur Zamarin [this message]
  -- strict thread matches above, loose matches on Subject: below --
2025-10-25  1:07 [gentoo-commits] repo/gentoo:master commit in: media-video/qmplay2/ Sam James
2025-09-12 13:40 Arthur Zamarin
2025-09-05  8:10 Arthur Zamarin
2025-08-18 14:08 Sam James
2025-06-28  6:24 Arthur Zamarin
2025-06-28  6:24 Arthur Zamarin
2025-06-26  3:11 Sam James
2025-06-13  7:34 Arthur Zamarin
2025-06-13  7:34 Arthur Zamarin
2025-02-18 22:10 Sam James
2025-01-22 17:40 Arthur Zamarin
2025-01-22 17:34 Arthur Zamarin
2025-01-08 20:43 Sam James
2024-12-30 20:02 Arthur Zamarin
2024-12-28 18:18 Arthur Zamarin
2024-12-28  0:05 Andreas Sturmlechner
2024-12-25 19:51 Arthur Zamarin
2024-12-13 10:15 Arthur Zamarin
2024-07-20 12:38 Arthur Zamarin
2024-07-20 11:14 Arthur Zamarin
2024-07-20 10:58 Arthur Zamarin
2024-06-25 22:03 Sam James
2024-06-17 19:42 Arthur Zamarin
2024-05-25  5:05 Arthur Zamarin
2024-05-25  5:05 Arthur Zamarin
2024-05-24  6:18 Arthur Zamarin
2024-04-19  6:08 Arthur Zamarin
2024-04-08 19:52 Arthur Zamarin
2024-04-08 15:30 Arthur Zamarin
2024-04-04 16:32 Arthur Zamarin
2024-04-03  9:23 Arthur Zamarin
2024-03-16 16:33 Arthur Zamarin
2024-03-08 11:33 Arthur Zamarin
2024-02-20 14:30 Arthur Zamarin
2024-02-15 13:04 Ionen Wolkens
2023-12-05  7:53 Arthur Zamarin
2023-11-04 20:14 Arthur Zamarin
2023-10-23  8:26 Arthur Zamarin
2023-09-07 17:40 Arthur Zamarin
2023-09-07 17:40 Arthur Zamarin
2023-08-22 19:48 Arthur Zamarin
2023-08-22 19:48 Arthur Zamarin
2023-08-09 17:21 Arthur Zamarin
2023-08-09 17:21 Arthur Zamarin
2023-06-28 18:30 Arthur Zamarin
2023-06-17 19:32 Arthur Zamarin
2023-06-09 14:42 Arthur Zamarin
2023-06-04 17:03 Arthur Zamarin
2023-05-30 19:39 Andreas Sturmlechner
2023-05-23  2:52 Sam James
2023-02-18 13:23 Arthur Zamarin
2023-02-17 19:08 Arthur Zamarin
2023-02-17 19:08 Arthur Zamarin
2022-10-17 17:32 Arthur Zamarin
2022-08-26 18:52 Arthur Zamarin
2022-07-29 10:52 Arthur Zamarin
2022-04-19  5:51 Arthur Zamarin
2022-04-19  5:51 Arthur Zamarin
2022-04-19  5:51 Arthur Zamarin
2022-01-29  9:13 Arthur Zamarin
2022-01-29  9:13 Arthur Zamarin
2022-01-29  9:13 Arthur Zamarin
2021-08-22 19:10 Arthur Zamarin
2021-08-22 18:49 Arthur Zamarin
2021-08-22 17:42 Arthur Zamarin
2021-08-22 17:42 Arthur Zamarin
2021-08-22 17:42 Arthur Zamarin
2021-04-06 21:17 Sam James
2021-03-31 11:09 Joonas Niilola
2021-03-31 11:09 Joonas Niilola
2021-03-20  8:48 Joonas Niilola
2020-08-05 12:19 Joonas Niilola
2020-06-23  8:36 Joonas Niilola
2020-05-06 11:51 Joonas Niilola
2020-03-14 12:07 Joonas Niilola
2020-01-19 23:53 Andreas Sturmlechner
2020-01-19 23:53 Andreas Sturmlechner
2019-12-22 17:21 Joonas Niilola
2019-12-22 16:59 Joonas Niilola

find likely ancestor, descendant, or conflicting patches for this message:
( dfblob:ed17f369d9c dfblob:5b3fa80658e dfblob:b7b2b595e0e )
 OR (
bs:"[gentoo-commits] repo/gentoo:master commit in: media-video/qmplay2/" )
	(help)

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=1655446847.eec9911da50c564c92f42b4d067cf977533d2655.arthurzam@gentoo \
    --to=arthurzam@gentoo.org \
    --cc=gentoo-commits@lists.gentoo.org \
    --cc=gentoo-dev@lists.gentoo.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link

Be sure your reply has a Subject: header at the top and a blank line before the message body.

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox