From: "Matt Turner" <mattst88@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-util/gnome-builder/
Date: Sun, 8 May 2022 04:22:08 +0000 (UTC) [thread overview]
Message-ID: <1651983672.ee7360dc60a70ef09d9425615bdb4deef4bc84d5.mattst88@gentoo> (raw)
commit: ee7360dc60a70ef09d9425615bdb4deef4bc84d5
Author: Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sat Feb 19 23:50:30 2022 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun May 8 04:21:12 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ee7360dc
dev-util/gnome-builder: Version bump to 42.1
Closes: https://bugs.gentoo.org/829838
Closes: https://bugs.gentoo.org/843224
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
dev-util/gnome-builder/Manifest | 1 +
dev-util/gnome-builder/gnome-builder-42.1.ebuild | 276 +++++++++++++++++++++++
dev-util/gnome-builder/metadata.xml | 1 +
3 files changed, 278 insertions(+)
diff --git a/dev-util/gnome-builder/Manifest b/dev-util/gnome-builder/Manifest
index 0b140c2c4500..65b62a9908fa 100644
--- a/dev-util/gnome-builder/Manifest
+++ b/dev-util/gnome-builder/Manifest
@@ -1 +1,2 @@
DIST gnome-builder-3.40.2.tar.xz 12083992 BLAKE2B 136c3e89378221116b5252a8472768888f11bd580cf9d1d524504f9000b8123ee479e19073630bb678cc7392b716e45d122b406dc7d44b13ba0ba77b435077e0 SHA512 e0d1f0f21fe0f681f87d1ad672cb5bf60df3ef16541fffd8ca62d447339371bdb5cbc10d8fc83496822d6eb35ad8078b095ff97d950d940d862d6fd7968147a4
+DIST gnome-builder-42.1.tar.xz 13276028 BLAKE2B 657e362ab9a2df1c70d9071ecc010747e5c73bbaa1c0d903778720e4fe874361013cfca3fe162328dfae180502c4fcc68ee01f04d1329add874b9e8db41abcd1 SHA512 a04a71efb163808ed4bfc446334b8f9cabe33cd33c977c9047e4fb00042b18cf7095217b2e287a45efda863ef479fce11435a2d24d489ba1816e3f36a561244e
diff --git a/dev-util/gnome-builder/gnome-builder-42.1.ebuild b/dev-util/gnome-builder/gnome-builder-42.1.ebuild
new file mode 100644
index 000000000000..140a6077d367
--- /dev/null
+++ b/dev-util/gnome-builder/gnome-builder-42.1.ebuild
@@ -0,0 +1,276 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+DISABLE_AUTOFORMATTING=1
+FORCE_PRINT_ELOG=1
+
+inherit gnome.org gnome2-utils llvm meson optfeature python-single-r1 readme.gentoo-r1 virtualx xdg
+
+DESCRIPTION="An IDE for writing GNOME-based software"
+HOMEPAGE="https://wiki.gnome.org/Apps/Builder https://gitlab.gnome.org/GNOME/gnome-builder"
+
+# FIXME: Review licenses at some point
+LICENSE="GPL-3+ GPL-2+ LGPL-3+ LGPL-2+ MIT CC-BY-SA-3.0 CC0-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="clang +devhelp doc flatpak +git +glade gtk-doc spell +sysprof test +webkit"
+REQUIRED_USE="
+ ${PYTHON_REQUIRED_USE}
+ flatpak? ( git )
+ devhelp? ( webkit )
+"
+
+# When bumping, pay attention to all the included plugins/*/meson.build (and other) build files and the requirements within.
+# `grep -rI dependency * --include='meson.build'` can give a good initial idea for external deps and their double checking.
+# The listed RDEPEND order shold roughly match that output as well, with toplevel one first then sorted by file path.
+# Most plugins have no extra requirements and default to enabled; we need to handle the ones with extra requirements. Many of
+# them have optional runtime dependencies, for which we try to at least notify the user via DOC_CONTENTS (but not all small
+# things); `grep -rI -e 'command-pattern.*=' -e 'push_arg'` can give a (spammy) idea, plus python imports in try/except.
+
+# Editorconfig needs old pcre, with vte migrating away, might want it optional or ported to pcre2?
+# An introspection USE flag of a dep is required if any introspection based language plugin wants to use it (grep for gi.repository). Last full check at 3.28.4
+
+# TODO: Handle llvm slots via llvm.eclass; see plugins/clang/meson.build
+RDEPEND="
+ >=dev-libs/libdazzle-3.37.0[introspection]
+ >=dev-libs/glib-2.69.1:2
+ >=x11-libs/gtk+-3.24:3[introspection]
+ >=x11-libs/gtksourceview-4.0.0:4[introspection]
+ >=gui-libs/libhandy-1.5.0:1[introspection]
+ >=dev-libs/json-glib-1.2.0
+ >=dev-libs/jsonrpc-glib-3.41.0
+ >=x11-libs/pango-1.38.0
+ >=dev-libs/libpeas-1.22.0[python,${PYTHON_SINGLE_USEDEP}]
+ dev-libs/libportal:=[gtk,introspection]
+ >=dev-libs/template-glib-3.28.0[introspection]
+ >=x11-libs/vte-0.65.0:2.91[introspection]
+ >=dev-libs/libxml2-2.9.0
+ webkit? ( >=net-libs/webkit-gtk-2.26:4=[introspection] )
+ sysprof? (
+ >=dev-util/sysprof-capture-3.37.1:4
+ >=dev-util/sysprof-3.37.1:0/4[gtk]
+ )
+ >=app-text/cmark-0.29.0:0=
+ flatpak? (
+ dev-util/ostree
+ >=net-libs/libsoup-2.52.0:2.4
+ >=sys-apps/flatpak-1.10.2
+ )
+ git? (
+ dev-libs/libgit2:=[ssh,threads]
+ >=dev-libs/libgit2-glib-0.28.0.1[ssh]
+ )
+ dev-libs/libpcre:3
+ dev-libs/libpcre2
+
+ >=dev-libs/gobject-introspection-1.54.0:=
+ $(python_gen_cond_dep '
+ >=dev-python/pygobject-3.22.0:3[${PYTHON_USEDEP}]
+ ')
+ ${PYTHON_DEPS}
+ clang? ( sys-devel/clang:= )
+ devhelp? ( >=dev-util/devhelp-3.25.1:= )
+ glade? ( >=dev-util/glade-3.22.0:3.10= )
+ spell? (
+ >=app-text/gspell-1.8:0=
+ app-text/enchant:2
+ )
+"
+DEPEND="${RDEPEND}"
+# TODO: runtime ctags path finding..
+
+# desktop-file-utils required for tests, but we have it in deptree for xdg update-desktop-database anyway, so be explicit and unconditional
+# appstream-glib needed for validation with appstream-util with FEATURES=test
+BDEPEND="
+ doc? (
+ $(python_gen_cond_dep '
+ dev-python/sphinx[${PYTHON_USEDEP}]
+ dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+ ')
+ )
+ gtk-doc? (
+ dev-util/gi-docgen
+ app-text/docbook-xml-dtd:4.3
+ )
+ test? (
+ dev-libs/appstream-glib
+ sys-apps/dbus
+ )
+ dev-util/desktop-file-utils
+ dev-util/glib-utils
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+"
+
+DOC_CONTENTS='gnome-builder can use various other dependencies on runtime to provide
+extra capabilities beyond these expressed via USE flags. Some of these
+that are currently available with packages include:
+
+* dev-util/uncrustify and dev-python/autopep8 for various Code Beautifier
+ plugin out of the box functionality.
+* dev-util/ctags with exuberant-ctags selected via "eselect ctags" for
+ C, C++, Python, JavaScript, CSS, HTML and Ruby autocompletion, semantic
+ highlighting and symbol resolving support.
+* dev-python/jedi and dev-python/lxml for more accurate Python
+ autocompletion support.
+* dev-util/valgrind for integration with valgrind.
+* dev-util/meson for integration with the Meson build system.
+* dev-util/cargo for integration with the Rust Cargo build system.
+* dev-util/cmake for integration with the CMake build system.
+* net-libs/nodejs[npm] for integration with the NPM package system.
+'
+# FIXME: Package codespell and mention here
+# FIXME: Package gnome-code-assistance and mention here, or maybe USE flag and default enable because it's rather important
+# eslint for additional diagnostics in JavaScript files (what package has this? At least something via NPM..)
+# jhbuild support
+# rust support via rust-analyzer; Go via go-langserver
+# autotools stuff for autotools plugin; gtkmm/autoconf-archive for C++ template
+# gjs/gettext/mono/PHPize stuff, but most of these are probably installed for other reasons anyways, when needed inside IDE
+# stylelint for stylesheet (CSS and co) linting
+# gvls for vala language-server integration
+
+llvm_check_deps() {
+ has_version "sys-devel/clang:${LLVM_SLOT}"
+}
+
+pkg_setup() {
+ python-single-r1_pkg_setup
+ use clang && llvm_pkg_setup
+}
+
+src_configure() {
+ local emesonargs=(
+ -Dtracing=false
+ -Dprofiling=false # not passing -pg to CFLAGS
+ -Dtcmalloc=false
+
+ -Dwith_safe_path=''
+
+ -Dgnome_sdk_version=master
+
+ -Dchannel=other
+
+ $(meson_use doc help)
+ $(meson_use gtk-doc docs)
+
+ -Dnetwork_tests=false
+
+ -Dctags_path=''
+
+ $(meson_feature webkit)
+
+ -Dplugin_autotools=true
+ -Dplugin_beautifier=true
+ -Dplugin_blueprint=true
+ -Dplugin_c_pack=true
+ -Dplugin_cargo=true
+ $(meson_use clang plugin_clang)
+ $(meson_use clang plugin_clangd)
+ $(meson_use clang plugin_clang_format)
+ -Dplugin_cmake=true
+ -Dplugin_codespell=true
+ -Dplugin_code_index=true
+ -Dplugin_color_picker=true
+ -Dplugin_copyright=true
+ -Dplugin_ctags=true
+ $(meson_use devhelp plugin_devhelp)
+ -Dplugin_deviced=false # libdeviced not packaged?
+ -Dplugin_dspy=true
+ -Dplugin_editorconfig=true # needs libpcre
+ -Dplugin_eslint=true
+ -Dplugin_file_search=true
+ $(meson_use flatpak plugin_flatpak)
+ -Dplugin_gdb=true
+ -Dplugin_gdiagnose=true
+ -Dplugin_gettext=true
+ $(meson_use git plugin_git)
+ -Dplugin_gjs_symbols=true
+ $(meson_use glade plugin_glade)
+ -Dplugin_gnome_code_assistance=true
+ -Dplugin_go_langserv=true
+ -Dplugin_gradle=true
+ -Dplugin_grep=true
+ -Dplugin_gvls=true
+ -Dplugin_html_completion=true
+ -Dplugin_html_preview=true
+ -Dplugin_intelephense=true
+ -Dplugin_jedi_language_server=true
+ -Dplugin_jhbuild=true
+ -Dplugin_make=true
+ -Dplugin_maven=true
+ -Dplugin_meson=true
+ -Dplugin_modelines=true
+ -Dplugin_mono=true
+ -Dplugin_newcomers=true
+ -Dplugin_notification=true
+ -Dplugin_npm=true
+ -Dplugin_phpize=true
+ -Dplugin_podman=true
+ -Dplugin_python_pack=true
+ -Dplugin_qemu=true
+ -Dplugin_quick_highlight=true
+ -Dplugin_retab=true
+ -Dplugin_rls=true
+ -Dplugin_rstcheck=true
+ -Dplugin_rubocop=true
+ -Dplugin_rust_analyzer=false # rust-analyzer not packaged
+ -Dplugin_shellcmd=true
+ $(meson_use spell plugin_spellcheck)
+ -Dplugin_stylelint=true
+ $(meson_use sysprof plugin_sysprof)
+ -Dplugin_sysroot=true
+ -Dplugin_todo=true
+ -Dplugin_ts_language_server=true
+ -Dplugin_update_manager=true
+ -Dplugin_vala=true
+ -Dplugin_vagrant=true
+ -Dplugin_valgrind=true
+ -Dplugin_vls=true
+ -Dplugin_waf=true
+ -Dplugin_words=true
+ -Dplugin_xml_pack=true
+ )
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+ python_optimize
+ if use doc; then
+ rm "${ED}"/usr/share/doc/gnome-builder/en/.buildinfo || die
+ rm "${ED}"/usr/share/doc/gnome-builder/en/objects.inv || die
+ # custom docdir in build system, blocked by https://github.com/mesonbuild/meson/issues/825
+ mv "${ED}"/usr/share/doc/gnome-builder/en "${ED}"/usr/share/doc/${PF}/html || die
+ # _sources subdir left in on purpose, as HTML links to the rst files as "View page source". Additionally default docompress exclusion of /html/ already ensures they aren't compressed, thus linkable as-is.
+ rmdir "${ED}"/usr/share/doc/gnome-builder/ || die
+ fi
+ readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_schemas_update
+ readme.gentoo_print_elog
+
+ optfeature_header "Code beautifiers"
+ optfeature "Python" dev-python/autopep8
+ optfeature "C/C++/Java" dev-util/uncrustify
+ optfeature "HTML" app-text/htmltidy
+
+ optfeature_header "Language support"
+ optfeature "Rust's Cargo build system" virtual/rust
+ optfeature "CMake" dev-util/cmake
+ optfeature "Java Maven build system" dev-java/maven-bin
+ optfeature "Meson Build system" dev-util/meson
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_schemas_update
+}
+
+src_test() {
+ virtx dbus-run-session meson test -C "${BUILD_DIR}"
+}
diff --git a/dev-util/gnome-builder/metadata.xml b/dev-util/gnome-builder/metadata.xml
index 342b0c570e2c..63870d032088 100644
--- a/dev-util/gnome-builder/metadata.xml
+++ b/dev-util/gnome-builder/metadata.xml
@@ -8,6 +8,7 @@
<use>
<flag name="clang">Provide integration with <pkg>sys-devel/clang</pkg> for best possible C/C++ autocompletion, semantic highlighting, symbol resolving, and diagnostics support</flag>
<flag name="devhelp">Provide API docs browsing and integration via <pkg>dev-util/devhelp</pkg></flag>
+ <flag name="flatpak">Enable support for flatpak applications using <pkg>sys-apps/flatpak</pkg></flag>
<flag name="git">Provide support for the Git version control system via <pkg>dev-libs/libgit2-glib</pkg>
(such as setup of Git for New Project, direct cloning for Open Project and changed lines indicators in the editor gutter)</flag>
<flag name="glade">Provide integration with <pkg>dev-util/glade</pkg> UI designer for Gtk</flag>
next reply other threads:[~2022-05-08 4:22 UTC|newest]
Thread overview: 58+ messages / expand[flat|nested] mbox.gz Atom feed top
2022-05-08 4:22 Matt Turner [this message]
-- strict thread matches above, loose matches on Subject: below --
2025-10-18 15:13 [gentoo-commits] repo/gentoo:master commit in: dev-util/gnome-builder/ Sam James
2025-10-18 15:13 Sam James
2025-10-18 15:13 Sam James
2025-10-13 3:02 Sam James
2025-08-05 10:37 Pacho Ramos
2025-08-05 10:37 Pacho Ramos
2025-07-29 11:43 Pacho Ramos
2025-06-29 9:37 Sam James
2025-02-20 10:20 Michał Górny
2025-01-16 16:55 Pacho Ramos
2025-01-16 16:55 Pacho Ramos
2024-11-09 10:40 Pacho Ramos
2024-11-09 10:40 Pacho Ramos
2024-05-10 7:20 Mart Raudsepp
2023-11-04 23:03 Mart Raudsepp
2023-11-04 23:03 Mart Raudsepp
2023-10-29 22:23 Mart Raudsepp
2023-05-05 9:01 Arthur Zamarin
2023-04-28 16:35 Matt Turner
2023-02-06 2:40 Matt Turner
2023-02-03 16:41 Matt Turner
2023-01-27 11:52 Mart Raudsepp
2022-12-16 20:37 Arthur Zamarin
2022-12-02 14:35 Matt Turner
2022-11-16 21:17 Matt Turner
2022-11-16 16:56 Matt Turner
2021-10-17 21:07 Mart Raudsepp
2021-05-06 6:09 Matt Turner
2021-05-06 6:09 Matt Turner
2021-04-30 16:39 Matt Turner
2021-04-29 1:02 Matt Turner
2021-04-19 0:46 Matt Turner
2021-04-12 22:16 Matt Turner
2021-02-06 9:59 Mart Raudsepp
2020-12-08 15:41 Mart Raudsepp
2020-08-14 20:45 Mart Raudsepp
2020-08-14 20:45 Mart Raudsepp
2020-07-28 6:52 Mart Raudsepp
2020-06-27 11:48 Mart Raudsepp
2020-06-18 11:27 Mart Raudsepp
2020-05-19 7:24 Mart Raudsepp
2020-04-17 19:50 Mart Raudsepp
2020-04-13 16:12 Agostino Sarubbo
2020-04-13 14:48 Agostino Sarubbo
2020-03-14 21:08 Mart Raudsepp
2020-02-29 21:22 Mart Raudsepp
2020-02-16 10:35 Mart Raudsepp
2020-02-11 13:00 Mart Raudsepp
2020-02-05 15:00 Mart Raudsepp
2019-03-30 16:30 Mart Raudsepp
2019-01-13 17:19 Mart Raudsepp
2018-12-17 15:08 Mart Raudsepp
2018-09-24 20:13 Mart Raudsepp
2018-09-12 14:39 Thomas Deutschmann
2018-04-29 0:08 Mart Raudsepp
2018-04-26 22:32 Aaron Bauman
2018-04-26 17:15 Thomas Deutschmann
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1651983672.ee7360dc60a70ef09d9425615bdb4deef4bc84d5.mattst88@gentoo \
--to=mattst88@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox