From: "Conrad Kostecki" <conikost@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: sys-apps/roccat-tools/
Date: Thu, 22 Jul 2021 20:09:00 +0000 (UTC) [thread overview]
Message-ID: <1626984524.d311d9b04463a0ce7c5f7a176db24a6920056304.conikost@gentoo> (raw)
commit: d311d9b04463a0ce7c5f7a176db24a6920056304
Author: Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Thu Jul 22 19:47:14 2021 +0000
Commit: Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Thu Jul 22 20:08:44 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d311d9b0
sys-apps/roccat-tools: drop old version
Closes: https://bugs.gentoo.org/781581
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>
.../roccat-tools/roccat-tools-5.9.0-r100.ebuild | 147 ---------------------
1 file changed, 147 deletions(-)
diff --git a/sys-apps/roccat-tools/roccat-tools-5.9.0-r100.ebuild b/sys-apps/roccat-tools/roccat-tools-5.9.0-r100.ebuild
deleted file mode 100644
index 1a5d2b88c0a..00000000000
--- a/sys-apps/roccat-tools/roccat-tools-5.9.0-r100.ebuild
+++ /dev/null
@@ -1,147 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-LUA_COMPAT=( lua5-1 luajit )
-
-inherit readme.gentoo-r1 cmake flag-o-matic lua-single toolchain-funcs udev user xdg
-
-DESCRIPTION="Utility for advanced configuration of Roccat devices"
-
-HOMEPAGE="http://roccat.sourceforge.net/"
-SRC_URI="mirror://sourceforge/roccat/${P}.tar.bz2"
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-IUSE_INPUT_DEVICES=(
- input_devices_roccat_arvo
- input_devices_roccat_isku
- input_devices_roccat_iskufx
- input_devices_roccat_kiro
- input_devices_roccat_kone
- input_devices_roccat_koneplus
- input_devices_roccat_konepure
- input_devices_roccat_konepuremilitary
- input_devices_roccat_konepureoptical
- input_devices_roccat_konextd
- input_devices_roccat_konextdoptical
- input_devices_roccat_kovaplus
- input_devices_roccat_kova2016
- input_devices_roccat_lua
- input_devices_roccat_nyth
- input_devices_roccat_pyra
- input_devices_roccat_ryosmk
- input_devices_roccat_ryosmkfx
- input_devices_roccat_ryostkl
- input_devices_roccat_savu
- input_devices_roccat_skeltr
- input_devices_roccat_sova
- input_devices_roccat_suora
- input_devices_roccat_tyon
-)
-
-IUSE="${IUSE_INPUT_DEVICES[@]}"
-
-REQUIRED_USE="
- input_devices_roccat_ryosmk? ( ${LUA_REQUIRED_USE} )
- input_devices_roccat_ryosmkfx? ( ${LUA_REQUIRED_USE} )
- input_devices_roccat_ryostkl? ( ${LUA_REQUIRED_USE} )
-"
-
-RDEPEND="
- dev-libs/dbus-glib
- dev-libs/glib:2
- >=dev-libs/libgaminggear-0.15.1
- dev-libs/libgudev:=
- sys-apps/dbus
- x11-libs/cairo
- x11-libs/gtk+:2
- x11-libs/libX11
- virtual/libusb:1
- input_devices_roccat_ryosmk? ( ${LUA_DEPS} )
- input_devices_roccat_ryosmkfx? ( ${LUA_DEPS} )
- input_devices_roccat_ryostkl? ( ${LUA_DEPS} )
-"
-
-DEPEND="
- ${RDEPEND}
-"
-BDEPEND="
- virtual/pkgconfig
-"
-
-PATCHES=(
- "${FILESDIR}"/${PN}-5.9.0-cmake_lua_impl.patch
-)
-
-DOCS=( Changelog KNOWN_LIMITATIONS README )
-
-pkg_setup() {
- # Don't bother checking all the relevant USE flags, this is harmless
- # to call even when no Lua implementations have been pulled in
- # by dependencies.
- lua-single_pkg_setup
-
- enewgroup roccat
-
- local model
- for model in ${IUSE_INPUT_DEVICES[@]} ; do
- use ${model} && USED_MODELS+="${model/input_devices_roccat_/;}"
- done
-}
-
-# Required because xdg.eclass overrides src_prepare() from cmake.eclass
-src_prepare() {
- cmake_src_prepare
-}
-
-src_configure() {
- if has_version \>=x11-libs/pango-1.44.0 ; then
- # Fix build with pango-1.44 which depends on harfbuzz
- local PKGCONF="$(tc-getPKG_CONFIG)"
- append-cflags "$(${PKGCONF} --cflags harfbuzz)"
- fi
-
- mycmakeargs=(
- -DDEVICES="${USED_MODELS/;/}"
- -DUDEVDIR="${EPREFIX}$(get_udevdir)/rules.d"
- )
-
- local lua_use=(
- input_devices_roccat_ryosmk
- input_devices_roccat_ryosmkfx
- input_devices_roccat_ryostkl
- )
- local luse
- for luse in ${lua_use[@]} ; do
- if use ${luse} ; then
- mycmakeargs+=(
- -DLUA_IMPL="${ELUA}"
- -DWITH_LUA="$(ver_cut 1-2 $(lua_get_version))"
- )
- break
- fi
- done
-
- cmake_src_configure
-}
-
-src_install() {
- cmake_src_install
- local stat_dir=/var/lib/roccat
- keepdir ${stat_dir}
- fowners root:roccat ${stat_dir}
- fperms 2770 ${stat_dir}
- readme.gentoo_create_doc
-}
-
-pkg_postinst() {
- xdg_pkg_postinst
- readme.gentoo_print_elog
- ewarn
- ewarn "This version breaks stored data for some devices. Before reporting bugs please delete"
- ewarn "affected folder(s) in /var/lib/roccat"
- ewarn
-}
next reply other threads:[~2021-07-22 20:09 UTC|newest]
Thread overview: 21+ messages / expand[flat|nested] mbox.gz Atom feed top
2021-07-22 20:09 Conrad Kostecki [this message]
-- strict thread matches above, loose matches on Subject: below --
2025-09-30 19:14 [gentoo-commits] repo/gentoo:master commit in: sys-apps/roccat-tools/ Andreas Sturmlechner
2021-07-22 20:09 Conrad Kostecki
2021-03-25 23:31 Conrad Kostecki
2020-01-13 11:41 Lars Wendler
2020-01-01 14:33 Lars Wendler
2019-07-24 5:47 Lars Wendler
2019-07-18 8:11 Lars Wendler
2019-07-17 13:10 Lars Wendler
2019-07-17 11:43 Michał Górny
2019-07-16 14:51 Michał Górny
2018-06-06 8:39 Andreas Sturmlechner
2017-07-17 9:08 Lars Wendler
2017-07-17 9:08 Lars Wendler
2016-07-03 22:57 Göktürk Yüksek
2016-03-24 19:20 Patrick Lauer
2016-03-24 11:35 Ian Delaney
2016-03-24 11:35 Ian Delaney
2015-09-15 20:40 Markos Chandras
2015-09-15 20:40 Markos Chandras
2015-09-15 20:40 Markos Chandras
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1626984524.d311d9b04463a0ce7c5f7a176db24a6920056304.conikost@gentoo \
--to=conikost@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox