From: "Conrad Kostecki" <conikost@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: media-sound/timidity++/
Date: Tue, 13 Jul 2021 20:57:29 +0000 (UTC) [thread overview]
Message-ID: <1626209701.63cb0ef9f7d3a92a4f06aebdf118ca677f5e9f2e.conikost@gentoo> (raw)
commit: 63cb0ef9f7d3a92a4f06aebdf118ca677f5e9f2e
Author: Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 13 19:08:54 2021 +0000
Commit: Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Tue Jul 13 20:55:01 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=63cb0ef9
media-sound/timidity++: migrate to GLEP 81
Bug: https://bugs.gentoo.org/781341
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>
media-sound/timidity++/timidity++-2.15.0-r1.ebuild | 211 +++++++++++++++++++++
1 file changed, 211 insertions(+)
diff --git a/media-sound/timidity++/timidity++-2.15.0-r1.ebuild b/media-sound/timidity++/timidity++-2.15.0-r1.ebuild
new file mode 100644
index 00000000000..efa232bbc9d
--- /dev/null
+++ b/media-sound/timidity++/timidity++-2.15.0-r1.ebuild
@@ -0,0 +1,211 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools desktop elisp-common systemd toolchain-funcs xdg
+
+MY_PV="${PV/_/-}"
+MY_P="TiMidity++-${MY_PV}"
+
+DESCRIPTION="A handy MIDI to WAV converter with OSS and ALSA output support"
+HOMEPAGE="http://timidity.sourceforge.net/"
+SRC_URI="mirror://sourceforge/timidity/${MY_P}.tar.xz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 ~hppa ppc ppc64 sparc x86"
+IUSE="alsa ao emacs flac gtk jack motif nas ncurses oss selinux slang speex tk vorbis X"
+
+REQUIRED_USE="tk? ( X )"
+
+DEPEND="
+ alsa? ( media-libs/alsa-lib )
+ ao? ( >=media-libs/libao-0.8.5 )
+ emacs? ( >=app-editors/emacs-23.1:* )
+ flac? ( media-libs/flac )
+ gtk? ( x11-libs/gtk+:2 )
+ jack? ( virtual/jack )
+ motif? ( >=x11-libs/motif-2.3:0 )
+ nas? ( >=media-libs/nas-1.4 )
+ ncurses? ( sys-libs/ncurses:0= )
+ slang? ( sys-libs/slang )
+ speex? ( media-libs/speex )
+ tk? ( dev-lang/tk:0= )
+ vorbis? ( media-libs/libvorbis )
+ X? (
+ media-libs/libpng:0=
+ x11-libs/libXaw
+ x11-libs/libXext
+ )
+"
+
+RDEPEND="
+ ${DEPEND}
+ acct-group/audio
+ acct-group/nobody
+ acct-user/timidity
+ app-eselect/eselect-timidity
+ alsa? ( media-sound/alsa-utils )
+ selinux? ( sec-policy/selinux-timidity )
+"
+
+PDEPEND="|| ( media-sound/timidity-eawpatches media-sound/timidity-freepats )"
+
+SITEFILE=50${PN}-gentoo.el
+
+DOCS=( AUTHORS ChangeLog NEWS README "${FILESDIR}"/timidity.cfg-r1 )
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-2.14.0-params.patch
+ "${FILESDIR}"/${PN}-2.14.0-ar.patch
+ "${FILESDIR}"/${PN}-2.14.0-configure-flags.patch
+ "${FILESDIR}"/${PN}-2.15.0-pkg-config.patch
+ "${FILESDIR}"/${PN}-2.14.0-CVE-2017-1154{6,7}.patch
+)
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+src_configure() {
+ export EXTRACFLAGS="${CFLAGS}" #385817
+
+ local audios
+ local myeconfargs=(
+ --localstatedir=/var/state/${PN}
+ --with-module-dir="${EPREFIX}/usr/share/timidity"
+ --with-lispdir="${SITELISP}/${PN}"
+ --with-elf
+ --enable-server
+ --enable-network
+ --enable-dynamic
+ --enable-vt100
+ --enable-spline=cubic
+ $(use_enable emacs)
+ $(use_enable slang)
+ $(use_enable ncurses)
+ $(use_with X x)
+ $(use_enable X spectrogram)
+ $(use_enable X wrd)
+ $(use_enable X xskin)
+ $(use_enable X xaw)
+ $(use_enable gtk)
+ $(use_enable tk tcltk)
+ $(use_enable motif)
+ )
+
+ use flac && audios+=",flac"
+ use speex && audios+=",speex"
+ use vorbis && audios+=",vorbis"
+ use oss && audios+=",oss"
+ use jack && audios+=",jack"
+ use ao && audios+=",ao"
+
+ if use nas; then
+ audios+=",nas"
+ myeconfargs+=(
+ --with-nas-library="/usr/$(get_libdir)/libaudio.so"
+ --with-x
+ )
+ use X || ewarn "Basic X11 support will be enabled because required by nas."
+ fi
+
+ if use alsa; then
+ audios+=",alsa"
+ myeconfargs+=(
+ --with-default-output=alsa
+ --enable-alsaseq
+ )
+ fi
+
+ if use motif; then
+ myeconfargs+=(
+ --with-x
+ )
+ use X || ewarn "Basic X11 support will be enabled because required by motif."
+ fi
+
+ # needs to come after all audios have been collected
+ myeconfargs+=(
+ --enable-audio=${audios}
+ )
+
+ econf "${myeconfargs[@]}"
+}
+
+src_install() {
+ emake DESTDIR="${D}" install
+ einstalldocs
+
+ # these are only for the ALSA sequencer mode
+ if use alsa; then
+ newconfd "${FILESDIR}"/conf.d.timidity.2 timidity
+ newinitd "${FILESDIR}"/init.d.timidity.4 timidity
+
+ systemd_dounit "${FILESDIR}"/timidity.service
+ fi
+
+ insinto /etc
+ newins "${FILESDIR}"/timidity.cfg-r1 timidity.cfg
+
+ dodir /usr/share/timidity
+ dosym ../../../etc/timidity.cfg /usr/share/timidity/timidity.cfg
+
+ if use emacs; then
+ elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+ fi
+
+ doicon "${FILESDIR}"/timidity.xpm
+ newmenu "${FILESDIR}"/timidity.desktop.2 timidity.desktop
+
+ # Order of preference: gtk, X (Xaw), ncurses, slang
+ # Do not create menu item for terminal ones
+ local interface="-id"
+ local terminal="true"
+ local nodisplay="true"
+ if use gtk || use X; then
+ interface="-ia"
+ terminal="false"
+ nodisplay="false"
+ use gtk && interface="-ig"
+ elif use ncurses || use slang; then
+ local interface="-is"
+ use ncurses && interface="-in"
+ fi
+ sed -e "s/Exec=timidity/Exec=timidity ${interface}/" \
+ -e "s/Terminal=.*/Terminal=${terminal}/" \
+ -e "s/NoDisplay=.*/NoDisplay=${nodisplay}/" \
+ -i "${ED}"/usr/share/applications/timidity.desktop || die
+}
+
+pkg_preinst() {
+ xdg_pkg_preinst
+}
+
+pkg_postinst() {
+ use emacs && elisp-site-regen
+
+ elog "A timidity config file has been installed in /etc/timidity.cfg."
+ elog "Do not edit this file as it will interfere with the eselect timidity tool."
+ elog "The tool 'eselect timidity' can be used to switch between installed patchsets."
+
+ if use alsa; then
+ elog "An init script for the alsa timidity sequencer has been installed."
+ elog "If you wish to use the timidity virtual sequencer, edit /etc/conf.d/timidity"
+ elog "and run 'rc-update add timidity <runlevel> && /etc/init.d/timidity start'"
+ fi
+
+ if use sparc; then
+ elog "Only saving to wave file and ALSA soundback has been tested working."
+ fi
+
+ xdg_pkg_postinst
+}
+
+pkg_postrm() {
+ use emacs && elisp-site-regen
+ xdg_pkg_postrm
+}
next reply other threads:[~2021-07-13 20:57 UTC|newest]
Thread overview: 36+ messages / expand[flat|nested] mbox.gz Atom feed top
2021-07-13 20:57 Conrad Kostecki [this message]
-- strict thread matches above, loose matches on Subject: below --
2024-11-26 6:33 [gentoo-commits] repo/gentoo:master commit in: media-sound/timidity++/ Sam James
2023-07-07 21:53 Conrad Kostecki
2023-04-16 12:11 WANG Xuerui
2022-10-21 4:01 Miroslav Šulc
2022-10-20 19:00 Jakov Smolić
2022-10-20 10:56 Jakov Smolić
2022-10-13 6:57 Agostino Sarubbo
2022-10-13 6:56 Agostino Sarubbo
2022-10-13 6:55 Agostino Sarubbo
2022-10-13 6:54 Agostino Sarubbo
2022-10-13 6:53 Agostino Sarubbo
2022-09-10 8:41 Sam James
2021-12-22 5:24 Sam James
2021-12-22 3:57 Sam James
2021-12-22 3:57 Sam James
2021-07-13 20:57 Conrad Kostecki
2021-01-03 12:10 Sergei Trofimovich
2021-01-01 11:21 Sergei Trofimovich
2020-12-31 3:25 Sam James
2020-12-31 1:47 Sam James
2020-12-30 2:39 Sam James
2020-08-08 8:49 Sergei Trofimovich
2020-07-26 0:46 Sam James
2020-07-10 0:15 Sam James
2019-03-12 8:42 Lars Wendler
2018-09-15 20:05 Andreas Sturmlechner
2018-09-03 18:57 Andreas Sturmlechner
2018-09-03 18:57 Andreas Sturmlechner
2018-09-02 23:46 Thomas Deutschmann
2018-09-01 23:26 Sergei Trofimovich
2018-09-01 23:22 Sergei Trofimovich
2018-08-30 6:16 Sergei Trofimovich
2018-08-28 12:52 Agostino Sarubbo
2018-01-01 18:38 Miroslav Šulc
2017-06-21 10:47 Alexis Ballier
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1626209701.63cb0ef9f7d3a92a4f06aebdf118ca677f5e9f2e.conikost@gentoo \
--to=conikost@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox