From: "Marek Szuba" <marecki@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: profiles/, dev-util/sysdig/
Date: Mon, 21 Dec 2020 12:08:43 +0000 (UTC) [thread overview]
Message-ID: <1608552510.9214bb519d3ef3e77027032a7ebafda6b80d4241.marecki@gentoo> (raw)
commit: 9214bb519d3ef3e77027032a7ebafda6b80d4241
Author: Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Mon Dec 21 12:02:05 2020 +0000
Commit: Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Mon Dec 21 12:08:30 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9214bb51
dev-util/sysdig: migrate to lua-single.eclass
We only support building sysdig against LuaJIT and while upstream build
scripts do include a check for PUC Lua 5.1, it is only run if LuaJIT couldn't
be found and using that implementation is not recommended:
"sysdig and its chisels are designed to be used with LuaJIT in Lua
5.1 mode. While it is possible to use sysdig with LuaJIT in Lua
5.2 mode or regular Lua, some chisels may not work as expected"
All in all, the changes have been rather trivial.
Closes: https://bugs.gentoo.org/752672
Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>
dev-util/sysdig/sysdig-0.27.1-r100.ebuild | 74 +++++++++++++++++++++++++++++++
profiles/package.mask | 1 +
2 files changed, 75 insertions(+)
diff --git a/dev-util/sysdig/sysdig-0.27.1-r100.ebuild b/dev-util/sysdig/sysdig-0.27.1-r100.ebuild
new file mode 100644
index 00000000000..d564a5f4f30
--- /dev/null
+++ b/dev-util/sysdig/sysdig-0.27.1-r100.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( luajit )
+# Documentation says this might be needed but since the unmigrated ebuilds
+# did not enforce it, nor does this one.
+#LUA_REQ_USE="-lua52compat"
+
+inherit bash-completion-r1 cmake lua-single
+
+DESCRIPTION="A system exploration and troubleshooting tool"
+HOMEPAGE="https://sysdig.com/"
+SRC_URI="https://github.com/draios/sysdig/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libressl +modules test"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="${LUA_DEPS}
+ app-misc/jq:0=
+ dev-cpp/tbb:0=
+ >=dev-libs/jsoncpp-0.6_pre:0=
+ dev-libs/libb64:0=
+ dev-libs/protobuf:0=
+ net-dns/c-ares:0=
+ net-libs/grpc:0=
+ sys-libs/ncurses:0=
+ sys-libs/zlib:0=
+ libressl? ( dev-libs/libressl:0= )
+ !libressl? ( dev-libs/openssl:0= )
+ net-misc/curl:0="
+DEPEND="${RDEPEND}
+ virtual/os-headers
+ test? ( dev-cpp/gtest )"
+PDEPEND="
+ modules? ( >=dev-util/sysdig-kmod-${PV} )"
+
+src_prepare() {
+ sed -i -e 's:-ggdb::' CMakeLists.txt || die
+
+ cmake_src_prepare
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DCREATE_TEST_TARGETS=$(usex test)
+
+ # done in dev-util/sysdig-kmod
+ -DBUILD_DRIVER=OFF
+ # libscap examples are not installed or really useful
+ -DBUILD_LIBSCAP_EXAMPLES=OFF
+
+ # unbundle the deps
+ -DUSE_BUNDLED_DEPS=OFF
+ )
+
+ cmake_src_configure
+}
+
+src_install() {
+ cmake_src_install
+
+ # remove sources
+ rm -r "${ED}"/usr/src || die
+
+ # move bashcomp to the proper location
+ dobashcomp "${ED}"/usr/etc/bash_completion.d/sysdig || die
+ rm -r "${ED}"/usr/etc || die
+}
diff --git a/profiles/package.mask b/profiles/package.mask
index ad5f5d56081..559d3760edb 100644
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -495,6 +495,7 @@ kde-apps/kdebase-meta:5
>=dev-lua/toluapp-1.0.93_p20190513-r100
>=dev-util/geany-plugins-1.37-r100
>=dev-util/hermes-2.8
+>=dev-util/sysdig-0.27.1-r100
=games-action/minetest-5.3.0-r100
>=games-arcade/jvgs-0.5-r100
>=games-emulation/fceux-2.2.3-r100
reply other threads:[~2020-12-21 12:08 UTC|newest]
Thread overview: [no followups] expand[flat|nested] mbox.gz Atom feed
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1608552510.9214bb519d3ef3e77027032a7ebafda6b80d4241.marecki@gentoo \
--to=marecki@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox