From: "Andreas Sturmlechner" <asturm@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: media-video/webcamoid/
Date: Sun, 19 Jul 2020 15:57:01 +0000 (UTC) [thread overview]
Message-ID: <1595173894.3e7b3f46e3340fc64573f82c773a897d1358b5dc.asturm@gentoo> (raw)
commit: 3e7b3f46e3340fc64573f82c773a897d1358b5dc
Author: reagentoo <reagentoo <AT> gmail <DOT> com>
AuthorDate: Sun Jul 19 13:19:02 2020 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Jul 19 15:51:34 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3e7b3f46
media-video/webcamoid-8.1.0: fix QML modules installation directory
Closes: https://bugs.gentoo.org/733220
Signed-off-by: Dmitry Baranov <reagentoo <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/16743
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
media-video/webcamoid/webcamoid-8.1.0-r1.ebuild | 100 ++++++++++++++++++++++++
1 file changed, 100 insertions(+)
diff --git a/media-video/webcamoid/webcamoid-8.1.0-r1.ebuild b/media-video/webcamoid/webcamoid-8.1.0-r1.ebuild
new file mode 100644
index 00000000000..42c60a85734
--- /dev/null
+++ b/media-video/webcamoid/webcamoid-8.1.0-r1.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PLOCALES="ca de el es et fr gl it ja kab ko nl pt ru uk zh_CN zh_TW"
+
+inherit l10n qmake-utils
+
+DESCRIPTION="A full featured webcam capture application"
+HOMEPAGE="https://webcamoid.github.io"
+SRC_URI="https://github.com/webcamoid/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+KEYWORDS="~amd64 ~x86"
+LICENSE="GPL-3"
+SLOT="0"
+
+IUSE_AVKYS=( alsa coreaudio ffmpeg gstreamer jack libuvc oss pulseaudio qtaudio v4lutils videoeffects )
+IUSE="${IUSE_AVKYS[@]} debug headers v4l"
+
+REQUIRED_USE="
+ v4lutils? ( v4l )
+"
+
+RDEPEND="
+ dev-qt/qtconcurrent:5
+ dev-qt/qtcore:5
+ dev-qt/qtdeclarative:5
+ dev-qt/qtgui:5
+ dev-qt/qtnetwork:5
+ dev-qt/qtopengl:5
+ dev-qt/qtquickcontrols:5
+ dev-qt/qtsvg:5
+ dev-qt/qtwidgets:5
+ ffmpeg? ( media-video/ffmpeg:= )
+ gstreamer? ( >=media-libs/gstreamer-1.6.0 )
+ jack? ( virtual/jack )
+ libuvc? ( media-libs/libuvc )
+ pulseaudio? ( media-sound/pulseaudio )
+ qtaudio? ( dev-qt/qtmultimedia:5 )
+ v4l? ( media-libs/libv4l )
+"
+DEPEND="${RDEPEND}
+ dev-qt/linguist-tools:5
+ >=sys-kernel/linux-headers-3.6
+ virtual/pkgconfig
+"
+
+PATCHES=( "${FILESDIR}/${P}-ffmpeg-4.patch" )
+
+src_prepare() {
+ local tsdir="${S}/StandAlone/share/ts"
+ local mylrelease="$(qt5_get_bindir)"/lrelease
+
+ prepare_locale() {
+ "${mylrelease}" "${tsdir}/${1}.ts" || die "preparing ${1} locale failed"
+ }
+
+ rm_locale() {
+ sed -i \
+ -e '/.*share\/ts\/'${1}'\.qm.*/d' \
+ StandAlone/translations.qrc || die
+ }
+
+ rm ${tsdir}/*.qm
+
+ l10n_find_plocales_changes "${tsdir}" "" '.ts'
+ l10n_for_each_locale_do prepare_locale
+ l10n_for_each_disabled_locale_do rm_locale
+
+ default
+}
+
+src_configure() {
+ local myqmakeargs=(
+ "CONFIG+=debug"
+ "PREFIX=/usr"
+ "BUILDDOCS=0"
+ "INSTALLDEVHEADERS=$(usex headers 1 0)"
+ "INSTALLQMLDIR=$(qt5_get_libdir)/qt5/qml"
+ "LIBDIR=/usr/$(get_libdir)"
+ "NOAVFOUNDATION=1"
+ "NODSHOW=1"
+ "NOVCAMWIN=1"
+ "NOWASAPI=1"
+ )
+
+ use v4l || myqmakeargs+=( "NOV4L2=1" )
+
+ for x in ${IUSE_AVKYS[@]}; do
+ use ${x} || myqmakeargs+=( "NO${x^^}=1" )
+ done
+
+ eqmake5 ${myqmakeargs[@]}
+}
+
+src_install() {
+ emake INSTALL_ROOT="${D}" install
+ einstalldocs
+}
next reply other threads:[~2020-07-19 15:57 UTC|newest]
Thread overview: 27+ messages / expand[flat|nested] mbox.gz Atom feed top
2020-07-19 15:57 Andreas Sturmlechner [this message]
-- strict thread matches above, loose matches on Subject: below --
2025-02-17 20:20 [gentoo-commits] repo/gentoo:master commit in: media-video/webcamoid/ Andreas Sturmlechner
2025-02-17 20:20 Andreas Sturmlechner
2025-02-17 20:20 Andreas Sturmlechner
2025-01-06 22:58 Andreas Sturmlechner
2024-07-08 3:19 Eli Schwartz
2024-07-08 3:19 Eli Schwartz
2023-08-17 7:39 Joonas Niilola
2023-08-17 7:39 Joonas Niilola
2023-05-29 12:23 Andreas Sturmlechner
2023-05-29 12:23 Andreas Sturmlechner
2023-05-29 12:23 Andreas Sturmlechner
2022-11-11 18:13 Joonas Niilola
2022-11-11 18:13 Joonas Niilola
2022-11-11 17:41 Joonas Niilola
2022-11-11 11:14 Joonas Niilola
2022-11-11 8:34 Joonas Niilola
2022-11-11 8:34 Joonas Niilola
2022-03-08 14:52 Jonas Stein
2022-02-17 21:23 Jonas Stein
2021-02-21 15:25 Joonas Niilola
2020-12-02 23:21 Sam James
2020-11-23 16:14 Joonas Niilola
2020-07-19 15:57 Andreas Sturmlechner
2020-07-19 15:57 Andreas Sturmlechner
2020-04-26 8:08 Mikle Kolyada
2017-12-30 18:17 Aaron Swenson
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1595173894.3e7b3f46e3340fc64573f82c773a897d1358b5dc.asturm@gentoo \
--to=asturm@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox