From: "Andreas Sturmlechner" <asturm@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: sci-libs/dlib/
Date: Fri, 5 Jun 2020 22:36:31 +0000 (UTC) [thread overview]
Message-ID: <1591396562.11546b57ee1c41f66f6e87a591d78356402f46e8.asturm@gentoo> (raw)
commit: 11546b57ee1c41f66f6e87a591d78356402f46e8
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Jun 5 21:46:17 2020 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Jun 5 22:36:02 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=11546b57
sci-libs/dlib: EAPI-7 bump, cmake.eclass, drop IUSE="static-libs"
EAPI-7 gives us BUILD_SHARED_LIBS=ON by default.
Closes: https://bugs.gentoo.org/725466
Closes: https://bugs.gentoo.org/708330
Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
sci-libs/dlib/dlib-19.16-r1.ebuild | 106 +++++++++++++++++++++++++++++++++++++
1 file changed, 106 insertions(+)
diff --git a/sci-libs/dlib/dlib-19.16-r1.ebuild b/sci-libs/dlib/dlib-19.16-r1.ebuild
new file mode 100644
index 00000000000..8baa4aca61b
--- /dev/null
+++ b/sci-libs/dlib/dlib-19.16-r1.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+DISTUTILS_OPTIONAL=1
+inherit cmake cuda distutils-r1
+
+DESCRIPTION="Numerical and networking C++ library"
+HOMEPAGE="http://dlib.net/"
+SRC_URI="https://github.com/davisking/dlib/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Boost-1.0"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="cblas cuda debug examples gif jpeg lapack mkl png python sqlite test X cpu_flags_x86_avx cpu_flags_x86_sse2 cpu_flags_x86_sse4_1"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RESTRICT="!test? ( test )"
+
+# doc needs a bunch of deps not in portage
+RDEPEND="
+ cblas? ( virtual/cblas )
+ cuda? ( dev-libs/cudnn:= )
+ gif? ( media-libs/giflib:= )
+ jpeg? ( virtual/jpeg:0= )
+ lapack? ( virtual/lapack )
+ mkl? ( sci-libs/mkl )
+ png? ( media-libs/libpng:0= )
+ python? ( ${PYTHON_DEPS} )
+ sqlite? ( dev-db/sqlite:3 )
+ X? ( x11-libs/libX11 )"
+DEPEND="${RDEPEND}"
+BDEPEND="python? ( test? ( dev-python/pytest[${PYTHON_USEDEP}] ) )"
+
+DOCS=( docs/README.txt )
+
+src_prepare() {
+ use cuda && cuda_src_prepare
+ cmake_src_prepare
+ use python && distutils-r1_src_prepare
+}
+
+python_configure_all() {
+ mydistutilsargs=(
+ --"$(usex gif)" DLIB_GIF_SUPPORT
+ --"$(usex jpeg)" DLIB_JPEG_SUPPORT
+ --"$(usex png)" DLIB_PNG_SUPPORT
+ --"$(usex X no yes)" DLIB_NO_GUI_SUPPORT
+ --"$(usex cblas)" DLIB_USE_BLAS
+ --"$(usex cuda)" DLIB_USE_CUDA
+ --"$(usex lapack)" DLIB_USE_LAPACK
+ --"$(usex cpu_flags_x86_avx)" USE_AVX_INSTRUCTIONS
+ --"$(usex cpu_flags_x86_sse2)" USE_SSE2_INSTRUCTIONS
+ --"$(usex cpu_flags_x86_sse4_1)" USE_SSE4_INSTRUCTIONS
+ )
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DDLIB_ENABLE_ASSERTS="$(usex debug)"
+ -DDLIB_ENABLE_STACK_TRACE="$(usex debug)"
+ -DDLIB_GIF_SUPPORT="$(usex gif)"
+ -DDLIB_JPEG_SUPPORT="$(usex jpeg)"
+ -DDLIB_PNG_SUPPORT="$(usex png)"
+ -DDLIB_LINK_WITH_SQLITE3="$(usex sqlite)"
+ -DDLIB_NO_GUI_SUPPORT="$(usex X OFF ON)"
+ -DDLIB_USE_BLAS="$(usex cblas)"
+ -DDLIB_USE_CUDA="$(usex cuda)"
+ -DDLIB_USE_LAPACK="$(usex lapack)"
+ -DUSE_AVX_INSTRUCTIONS="$(usex cpu_flags_x86_avx)"
+ -DUSE_SSE2_INSTRUCTIONS="$(usex cpu_flags_x86_sse2)"
+ -DUSE_SSE4_INSTRUCTIONS="$(usex cpu_flags_x86_sse4_1)"
+ )
+ cmake_src_configure
+ use python && distutils-r1_src_configure
+}
+
+src_compile() {
+ cmake_src_compile
+ use python && distutils-r1_src_compile
+}
+
+python_test() {
+ esetup.py test
+}
+
+src_test() {
+ mkdir "${BUILD_DIR}"/dlib/test || die
+ pushd "${BUILD_DIR}"/dlib/test > /dev/null || die
+ cmake "${S}"/dlib/test || die
+ emake
+ ./dtest --runall || die
+ popd > /dev/null || die
+ use python && distutils-r1_src_test
+}
+
+src_install() {
+ cmake_src_install
+ use python && distutils-r1_src_install
+ if use examples; then
+ dodoc -r examples
+ docompress -x /usr/share/doc/${PF}
+ fi
+}
next reply other threads:[~2020-06-05 22:36 UTC|newest]
Thread overview: 15+ messages / expand[flat|nested] mbox.gz Atom feed top
2020-06-05 22:36 Andreas Sturmlechner [this message]
-- strict thread matches above, loose matches on Subject: below --
2023-06-08 10:14 [gentoo-commits] repo/gentoo:master commit in: sci-libs/dlib/ Pacho Ramos
2022-08-06 2:55 Sam James
2022-07-06 16:53 Andrew Ammerlaan
2021-05-27 21:06 David Seifert
2021-03-31 11:41 David Seifert
2021-01-01 1:56 Michał Górny
2020-06-05 22:36 Andreas Sturmlechner
2020-06-05 22:36 Andreas Sturmlechner
2019-12-12 14:58 Michał Górny
2019-08-13 7:40 Michał Górny
2019-03-02 20:11 Andreas Sturmlechner
2018-07-13 10:33 Tony Vroon
2017-11-06 7:03 Amy Liffey
2017-07-27 18:51 Sebastien Fabbro
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1591396562.11546b57ee1c41f66f6e87a591d78356402f46e8.asturm@gentoo \
--to=asturm@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox