[gentoo-commits] repo/gentoo:master commit in: net-p2p/amule/

public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed

From: "Joonas Niilola" <juippis@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: net-p2p/amule/
Date: Thu, 20 Feb 2020 13:27:28 +0000 (UTC)	[thread overview]
Message-ID: <1582204640.6b0c497b4d0f022fc6fe3179e4c62e4cb92e8437.juippis@gentoo> (raw)

commit:     6b0c497b4d0f022fc6fe3179e4c62e4cb92e8437
Author:     Alexander Tsoy <alexander <AT> tsoy <DOT> me>
AuthorDate: Mon Feb  3 08:10:41 2020 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Thu Feb 20 13:17:20 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6b0c497b

net-p2p/amule: add live ebuild

Closes: https://bugs.gentoo.org/362781
Signed-off-by: Alexander Tsoy <alexander <AT> tsoy.me>
Closes: https://github.com/gentoo/gentoo/pull/14537
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 net-p2p/amule/amule-9999.ebuild | 141 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 141 insertions(+)

diff --git a/net-p2p/amule/amule-9999.ebuild b/net-p2p/amule/amule-9999.ebuild
new file mode 100644
index 00000000000..c18f9ad656b
--- /dev/null
+++ b/net-p2p/amule/amule-9999.ebuild
@@ -0,0 +1,141 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+WX_GTK_VER="3.0-gtk3"
+
+inherit wxwidgets xdg-utils
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/amule-project/amule"
+	inherit autotools git-r3
+else
+	MY_P="${PN/m/M}-${PV}"
+	SRC_URI="https://download.sourceforge.net/${PN}/${MY_P}.tar.xz"
+	S="${WORKDIR}/${MY_P}"
+	KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+DESCRIPTION="aMule, the all-platform eMule p2p client"
+HOMEPAGE="http://www.amule.org/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="daemon debug geoip nls remote stats upnp +X"
+
+RDEPEND="
+	dev-libs/boost:=
+	dev-libs/crypto++:=
+	sys-libs/binutils-libs:0=
+	sys-libs/zlib
+	>=x11-libs/wxGTK-3.0.4:${WX_GTK_VER}[X?]
+	daemon? ( acct-user/amule )
+	geoip? ( dev-libs/geoip )
+	nls? ( virtual/libintl )
+	remote? (
+		acct-user/amule
+		media-libs/libpng:0=
+	)
+	stats? ( media-libs/gd:=[jpeg,png] )
+	upnp? ( net-libs/libupnp:0 )
+"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+	X? ( dev-util/desktop-file-utils )
+"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+)
+
+pkg_setup() {
+	setup-wxwidgets
+}
+
+src_prepare() {
+	default
+
+	if [[ "${PV}" == *9999 ]]; then
+		./autogen.sh || die
+	fi
+}
+
+src_configure() {
+	local myconf=(
+		--with-denoise-level=0
+		--with-wx-config="${WX_CONFIG}"
+		--enable-amulecmd
+		--with-boost
+		$(use_enable debug)
+		$(use_enable daemon amule-daemon)
+		$(use_enable geoip)
+		$(use_enable nls)
+		$(use_enable remote webserver)
+		$(use_enable stats cas)
+		$(use_enable stats alcc)
+		$(use_enable upnp)
+	)
+
+	if use X; then
+		myconf+=(
+			$(use_enable remote amule-gui)
+			$(use_enable stats alc)
+			$(use_enable stats wxcas)
+		)
+	else
+		myconf+=(
+			--disable-monolithic
+			--disable-amule-gui
+			--disable-alc
+			--disable-wxcas
+		)
+	fi
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	if use daemon; then
+		newconfd "${FILESDIR}"/amuled.confd-r1 amuled
+		newinitd "${FILESDIR}"/amuled.initd amuled
+	fi
+	if use remote; then
+		newconfd "${FILESDIR}"/amuleweb.confd-r1 amuleweb
+		newinitd "${FILESDIR}"/amuleweb.initd amuleweb
+	fi
+
+	if use daemon || use remote; then
+		keepdir /var/lib/${PN}
+		fowners amule:amule /var/lib/${PN}
+		fperms 0750 /var/lib/${PN}
+	fi
+}
+
+pkg_postinst() {
+	local ver
+
+	if use daemon || use remote; then
+		for ver in ${REPLACING_VERSIONS}; do
+			if ver_test ${ver} -lt "2.3.2-r4"; then
+				elog "Default user under which amuled and amuleweb daemons are started"
+				elog "have been changed from p2p to amule. Default home directory have been"
+				elog "changed as well."
+				echo
+				elog "If you want to preserve old download/share location, you can create"
+				elog "symlink /var/lib/amule/.aMule pointing to the old location and adjust"
+				elog "files ownership *or* restore AMULEUSER and AMULEHOME variables in"
+				elog "/etc/conf.d/{amuled,amuleweb} to the old values."
+
+				break
+			fi
+		done
+	fi
+
+	use X && xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	use X && xdg_desktop_database_update
+}

next             reply	other threads:[~2020-02-20 13:27 UTC|newest]

Thread overview: 53+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2020-02-20 13:27 Joonas Niilola [this message]
  -- strict thread matches above, loose matches on Subject: below --
2025-09-18 21:44 [gentoo-commits] repo/gentoo:master commit in: net-p2p/amule/ Sam James
2025-05-17 15:53 Sam James
2025-05-17 14:58 David Seifert
2025-05-05  6:18 Arthur Zamarin
2025-05-03 18:24 Arthur Zamarin
2025-04-28 12:36 Arthur Zamarin
2025-02-17  9:26 Ulrich Müller
2024-10-07 12:39 Yixun Lan
2024-07-13 11:06 Yixun Lan
2024-07-05 17:49 Pacho Ramos
2024-04-12  8:12 Joonas Niilola
2024-04-11 17:40 Arthur Zamarin
2024-04-11 16:57 Arthur Zamarin
2023-12-22  6:46 Sam James
2023-12-20  6:23 Arthur Zamarin
2023-12-20  6:23 Arthur Zamarin
2023-12-20  6:23 Arthur Zamarin
2023-12-20  3:44 Sam James
2023-06-27  0:02 Yixun Lan
2023-06-26 14:43 Sam James
2022-04-28 15:05 Jakov Smolić
2021-06-20  7:52 Agostino Sarubbo
2021-06-20  7:51 Agostino Sarubbo
2021-06-20  7:50 Agostino Sarubbo
2021-06-20  7:50 Agostino Sarubbo
2021-02-22 14:47 Joonas Niilola
2020-06-15 15:16 Agostino Sarubbo
2020-06-14 20:19 Sergei Trofimovich
2020-06-14 20:08 Sergei Trofimovich
2020-04-30 12:00 Joonas Niilola
2020-04-30 12:00 Joonas Niilola
2020-02-20 13:27 Joonas Niilola
2020-01-17  6:23 Joonas Niilola
2018-10-06 19:12 Sergei Trofimovich
2018-07-29 10:35 Sergei Trofimovich
2018-07-23 13:10 Tobias Klausmann
2018-07-21 17:50 Mikle Kolyada
2018-06-22 22:17 Patrice Clement
2018-06-22 22:17 Patrice Clement
2018-06-22 22:17 Patrice Clement
2018-06-22 22:17 Patrice Clement
2017-06-13 12:31 Agostino Sarubbo
2017-06-08 10:16 Agostino Sarubbo
2017-04-05 14:22 Michael Weber
2017-03-27  2:19 Michael Orlitzky
2017-03-27  2:19 Michael Orlitzky
2016-10-01 14:19 Pacho Ramos
2016-05-03 17:35 Austin English
2016-01-22 10:43 Patrice Clement
2016-01-22 10:43 Patrice Clement
2016-01-22 10:43 Patrice Clement
2015-11-07 12:57 Pacho Ramos

find likely ancestor, descendant, or conflicting patches for this message:
( dfblob:c18f9ad656 )
 OR (
bs:"[gentoo-commits] repo/gentoo:master commit in: net-p2p/amule/" )
	(help)

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=1582204640.6b0c497b4d0f022fc6fe3179e4c62e4cb92e8437.juippis@gentoo \
    --to=juippis@gentoo.org \
    --cc=gentoo-commits@lists.gentoo.org \
    --cc=gentoo-dev@lists.gentoo.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link

Be sure your reply has a Subject: header at the top and a blank line before the message body.

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox