[gentoo-commits] repo/gentoo:master commit in: media-libs/avidemux-plugins/

public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed

From: "Stefan Strogin" <steils@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: media-libs/avidemux-plugins/
Date: Wed, 14 Aug 2019 02:24:13 +0000 (UTC)	[thread overview]
Message-ID: <1565749007.5d9bb5b2019d9756f0c68957121c977f607f45e8.steils@gentoo> (raw)

commit:     5d9bb5b2019d9756f0c68957121c977f607f45e8
Author:     Stefan Strogin <steils <AT> gentoo <DOT> org>
AuthorDate: Wed Aug 14 01:57:38 2019 +0000
Commit:     Stefan Strogin <steils <AT> gentoo <DOT> org>
CommitDate: Wed Aug 14 02:16:47 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5d9bb5b2

media-libs/avidemux-plugins: bump version to 2.7.3

Bug: https://bugs.gentoo.org/657386
Package-Manager: Portage-2.3.71, Repoman-2.3.17
Signed-off-by: Stefan Strogin <steils <AT> gentoo.org>

 media-libs/avidemux-plugins/Manifest               |   1 +
 .../avidemux-plugins/avidemux-plugins-2.7.3.ebuild | 165 +++++++++++++++++++++
 2 files changed, 166 insertions(+)

diff --git a/media-libs/avidemux-plugins/Manifest b/media-libs/avidemux-plugins/Manifest
index 281d961cf75..e9ad4687cc9 100644
--- a/media-libs/avidemux-plugins/Manifest
+++ b/media-libs/avidemux-plugins/Manifest
@@ -1 +1,2 @@
+DIST 2.7.3.tar.gz 23772654 BLAKE2B f946c267140bc8aebda2ce027ed8cb7c84a98a401255d3e0cdaf7498680e8bd9c78a33c122cb177d397ed2dd6bc3c29d7508578028c2964c2897279bf860b62d SHA512 d7761de1c40de1b824efbcf24173ea738a2e0ba7fa41cefa09e7bac3ec97f3af4b04201e36f9de50ade2b09e394aa99ed1d4907f90bb132f9896e8f1b5e82d7a
 DIST avidemux_2.7.0.tar.gz 21474504 BLAKE2B c6e55a0b5220d6d3746fa06162bf11253145fd28f2f6f744702d5e0342fba85e546a28883eb847139eadd34c94037ebc7d68f5576e7505a85288556468d14b96 SHA512 7c92213d3bd2849dbdb5a1aff2acd6da231fd76c561b756fbf4a1d5a41e9705d609d7a35b6ca6b77ceb3bf5138f861cd24ed16d8fcec4fd713f09a2ff07e9015

diff --git a/media-libs/avidemux-plugins/avidemux-plugins-2.7.3.ebuild b/media-libs/avidemux-plugins/avidemux-plugins-2.7.3.ebuild
new file mode 100644
index 00000000000..fbe10c0bf2c
--- /dev/null
+++ b/media-libs/avidemux-plugins/avidemux-plugins-2.7.3.ebuild
@@ -0,0 +1,165 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_MAKEFILE_GENERATOR="emake"
+PYTHON_COMPAT=( python{2_7,3_6} )
+
+inherit cmake-utils python-single-r1
+
+DESCRIPTION="Plugins for the video editor media-video/avidemux"
+HOMEPAGE="http://fixounet.free.fr/avidemux"
+SRC_URI="https://github.com/mean00/avidemux2/archive/${PV}.tar.gz"
+
+# Multiple licenses because of all the bundled stuff.
+LICENSE="GPL-1 GPL-2 MIT PSF-2 public-domain"
+SLOT="2.7"
+IUSE="a52 aac aften alsa amr dcaenc debug dts fdk fontconfig fribidi jack lame libsamplerate cpu_flags_x86_mmx nvenc opengl opus oss pulseaudio qt5 truetype twolame vdpau vorbis vpx x264 x265 xv xvid"
+KEYWORDS="~amd64 ~x86"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	~media-libs/avidemux-core-${PV}:${SLOT}[vdpau?]
+	~media-video/avidemux-${PV}:${SLOT}[opengl?,qt5?]
+	>=dev-lang/spidermonkey-1.5-r2:0=
+	dev-libs/libxml2:2
+	media-libs/a52dec:0
+	media-libs/libass:0=
+	media-libs/libmad:0
+	media-libs/libmp4v2:0
+	media-libs/libpng:0=
+	virtual/libiconv:0
+	aac? (
+		>=media-libs/faac-1.29.9.2:0
+		media-libs/faad2:0
+	)
+	aften? ( media-libs/aften:0 )
+	alsa? ( >=media-libs/alsa-lib-1.0.3b-r2:0 )
+	amr? ( media-libs/opencore-amr:0 )
+	dcaenc? ( media-sound/dcaenc:0 )
+	dts? ( media-libs/libdca:0 )
+	fdk? ( media-libs/fdk-aac:0= )
+	fontconfig? ( media-libs/fontconfig:1.0 )
+	fribidi? ( dev-libs/fribidi:0 )
+	jack? (
+		media-sound/jack-audio-connection-kit:0
+		libsamplerate? ( media-libs/libsamplerate:0 )
+	)
+	lame? ( media-sound/lame:0 )
+	nvenc? ( amd64? ( media-video/nvidia_video_sdk:0 ) )
+	opus? ( media-libs/opus:0 )
+	pulseaudio? ( media-sound/pulseaudio:0 )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)
+	truetype? ( media-libs/freetype:2 )
+	twolame? ( media-sound/twolame:0 )
+	vorbis? ( media-libs/libvorbis:0 )
+	vpx? ( media-libs/libvpx:0= )
+	x264? ( media-libs/x264:0= )
+	x265? ( media-libs/x265:0= )
+	xv? (
+		x11-libs/libX11:0
+		x11-libs/libXext:0
+		x11-libs/libXv:0
+	)
+	xvid? ( media-libs/xvid:0 )
+"
+DEPEND="${COMMON_DEPEND}
+	oss? ( virtual/os-headers:0 )
+"
+RDEPEND="${COMMON_DEPEND}
+	!<media-libs/avidemux-plugins-${PV}
+"
+
+S="${WORKDIR}/avidemux2-${PV}"
+
+PATCHES=( "${FILESDIR}"/${PN}-2.6.20-optional-pulse.patch )
+
+src_prepare() {
+	default
+
+	# Don't reapply PATCHES during cmake-utils_src_prepare
+	unset PATCHES
+
+	processes="buildPluginsCommon:avidemux_plugins
+		buildPluginsCLI:avidemux_plugins"
+	use qt5 && processes+=" buildPluginsQt4:avidemux_plugins"
+
+	for process in ${processes} ; do
+		CMAKE_USE_DIR="${S}"/${process#*:} cmake-utils_src_prepare
+	done
+}
+
+src_configure() {
+	# See bug 432322.
+	use x86 && replace-flags -O0 -O1
+
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+
+		local mycmakeargs=(
+			-DAVIDEMUX_SOURCE_DIR='${S}'
+			-DPLUGIN_UI=$(echo ${build/buildPlugins/} | tr '[:lower:]' '[:upper:]')
+			-DFAAC="$(usex aac)"
+			-DFAAD="$(usex aac)"
+			-DALSA="$(usex alsa)"
+			-DAFTEN="$(usex aften)"
+			-DDCAENC="$(usex dcaenc)"
+			-DFDK_AAC="$(usex fdk)"
+			-DOPENCORE_AMRWB="$(usex amr)"
+			-DOPENCORE_AMRNB="$(usex amr)"
+			-DLIBDCA="$(usex dts)"
+			-DFONTCONFIG="$(usex fontconfig)"
+			-DJACK="$(usex jack)"
+			-DLAME="$(usex lame)"
+			-DNVENC="$(usex nvenc)"
+			-DOPUS="$(usex opus)"
+			-DOSS="$(usex oss)"
+			-DPULSEAUDIOSIMPLE="$(usex pulseaudio)"
+			-DQT4=OFF
+			-DFREETYPE2="$(usex truetype)"
+			-DTWOLAME="$(usex twolame)"
+			-DX264="$(usex x264)"
+			-DX265="$(usex x265)"
+			-DXVIDEO="$(usex xv)"
+			-DXVID="$(usex xvid)"
+			-DVDPAU="$(usex vdpau)"
+			-DVORBIS="$(usex vorbis)"
+			-DLIBVORBIS="$(usex vorbis)"
+			-DVPXDEC="$(usex vpx)"
+			-DUSE_EXTERNAL_LIBA52=yes
+			-DUSE_EXTERNAL_LIBASS=yes
+			-DUSE_EXTERNAL_LIBMAD=yes
+			-DUSE_EXTERNAL_LIBMP4V2=yes
+		)
+
+		if use qt5 ; then
+			mycmakeargs+=( -DENABLE_QT5=True )
+		fi
+
+		if use debug ; then
+			mycmakeargs+=( -DVERBOSE=1 -DADM_DEBUG=1 )
+		fi
+
+		CMAKE_USE_DIR="${S}"/${process#*:} BUILD_DIR="${build}" cmake-utils_src_configure
+	done
+}
+
+src_compile() {
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		BUILD_DIR="${build}" cmake-utils_src_compile
+	done
+}
+
+src_install() {
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		BUILD_DIR="${build}" cmake-utils_src_install
+	done
+}

next             reply	other threads:[~2019-08-14  2:24 UTC|newest]

Thread overview: 32+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2019-08-14  2:24 Stefan Strogin [this message]
  -- strict thread matches above, loose matches on Subject: below --
2025-06-08  5:12 [gentoo-commits] repo/gentoo:master commit in: media-libs/avidemux-plugins/ Sam James
2025-06-08  5:12 Sam James
2025-06-08  5:12 Sam James
2024-06-03 12:44 Sam James
2024-04-26 12:50 Sam James
2023-05-31 11:51 Andreas Sturmlechner
2023-01-10  9:00 Sam James
2023-01-09  7:27 Sam James
2023-01-07  7:20 Sam James
2022-06-19  9:06 Jakov Smolić
2022-03-09 12:37 Sam James
2021-11-07  0:01 Sam James
2021-01-01  1:06 Michał Górny
2020-10-31 11:11 David Seifert
2020-08-07 23:24 Andreas Sturmlechner
2020-08-01 11:29 Miroslav Šulc
2020-02-10 12:12 Michał Górny
2019-08-28 22:52 Stefan Strogin
2019-08-25 20:52 Stefan Strogin
2019-08-14  4:35 Stefan Strogin
2019-07-11  7:49 Sven Wegener
2019-07-06 10:25 Andreas Sturmlechner
2019-07-06 10:25 Andreas Sturmlechner
2018-01-09 17:33 Andreas Sturmlechner
2018-01-09 17:33 Andreas Sturmlechner
2017-12-09 13:52 Andreas Sturmlechner
2017-12-09  9:50 Andreas Sturmlechner
2017-12-09  9:50 Andreas Sturmlechner
2017-12-08 18:32 Andreas Sturmlechner
2016-05-06  7:49 Patrick Lauer
2016-05-05 19:48 Michał Górny

find likely ancestor, descendant, or conflicting patches for this message:
( dfblob:281d961cf7 dfblob:e9ad4687cc dfblob:fbe10c0bf2 )
 OR (
bs:"[gentoo-commits] repo/gentoo:master commit in: media-libs/avidemux-plugins/" )
	(help)

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=1565749007.5d9bb5b2019d9756f0c68957121c977f607f45e8.steils@gentoo \
    --to=steils@gentoo.org \
    --cc=gentoo-commits@lists.gentoo.org \
    --cc=gentoo-dev@lists.gentoo.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link

Be sure your reply has a Subject: header at the top and a blank line before the message body.

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox