From: "Mart Raudsepp" <leio@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-util/gnome-builder/
Date: Sun, 13 Jan 2019 17:19:31 +0000 (UTC) [thread overview]
Message-ID: <1547399762.f3f2076b9715ecffe24fbc13222d24df3ca95367.leio@gentoo> (raw)
commit: f3f2076b9715ecffe24fbc13222d24df3ca95367
Author: Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 13 17:16:02 2019 +0000
Commit: Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Jan 13 17:16:02 2019 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f3f2076b
dev-util/gnome-builder: bump to 3.30.3
Most of what's in 3.30.3 was already included in our patchset on top
of 3.30.2, except some of the gdb integration improvements (and
french/spanish translation updates).
Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>
dev-util/gnome-builder/Manifest | 1 +
dev-util/gnome-builder/gnome-builder-3.30.3.ebuild | 181 +++++++++++++++++++++
2 files changed, 182 insertions(+)
diff --git a/dev-util/gnome-builder/Manifest b/dev-util/gnome-builder/Manifest
index 173a9e7e464..a9037663c70 100644
--- a/dev-util/gnome-builder/Manifest
+++ b/dev-util/gnome-builder/Manifest
@@ -2,3 +2,4 @@ DIST gnome-builder-3.24.2.tar.xz 4342908 BLAKE2B 5dca80d2e948041bc096fa9a2a5d393
DIST gnome-builder-3.28.4.tar.xz 9309060 BLAKE2B a4402452ffaf64cc767edb9cba65b74a88cb77d04ca2ffecd3b01c53382930891c2c03e2528861f4d28ca3643465b6767235e945f44cc37d2d716bcbb3ab25c8 SHA512 ef83b909f295d83478aa7d5deb8b5d8291ddf6134e147e88452cdba8ff449a2415d0381d63d3f82cf28942b1096a704de64540c8cdf5f06c21c8278c93fbbc03
DIST gnome-builder-3.30.2-patchset.tar.xz 43720 BLAKE2B c444117232c6560e68cad46134327e94b361cf89c4f68f2e68940e8a46d2a42720aa5e881dcb3153a3c75057cfacd8c67287a8bb0740999d4628ab6498db7c32 SHA512 e17a0357d2a3e6c059ef27dbf591ad3acfa6f5d7d58f47ca8ebc6dc6883a1bb1bb87b15f3c564c2babc5857e9de4a7a47934398d0000880f233265d7254087d3
DIST gnome-builder-3.30.2.tar.xz 9478508 BLAKE2B 546328df141582d0d15317166c27493ac1f0b813680607f05de3429301cf8e4937cfc51bff69db26cd4ef1a8ef02aadd5aaa643c857eeabf9b16606a2a3a5cda SHA512 39087e3a30a807b7374167ba4c5295a9161e3c8d8e409172dcd28c52db48e72cd9303c2d4ff8fd11d4bfc70af6c810e5dc254c4c74b646875206221cff3bad57
+DIST gnome-builder-3.30.3.tar.xz 9486164 BLAKE2B b983fd71b1bab31386ab8f4c3a6ff57b33afd2da5aff5e41e7d1cba388a9b6998a0f799c0843bde95f8ce0456fe46457d0c0c46622d59eeb7729d2e8868898f7 SHA512 468605dbd2bd712a76c333a974bb19ca889dfe8493c2e85101641034f3e2c8eba2c0ee2f98ad01f3466f0f42946f05790763ccfaf786d73da192d64360eec47f
diff --git a/dev-util/gnome-builder/gnome-builder-3.30.3.ebuild b/dev-util/gnome-builder/gnome-builder-3.30.3.ebuild
new file mode 100644
index 00000000000..16fbc931b48
--- /dev/null
+++ b/dev-util/gnome-builder/gnome-builder-3.30.3.ebuild
@@ -0,0 +1,181 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{4,5,6} )
+VALA_MIN_API_VERSION="0.36"
+DISABLE_AUTOFORMATTING=1
+FORCE_PRINT_ELOG=1
+
+inherit gnome.org gnome2-utils llvm meson python-single-r1 readme.gentoo-r1 vala virtualx xdg
+
+DESCRIPTION="An IDE for writing GNOME-based software"
+HOMEPAGE="https://wiki.gnome.org/Apps/Builder"
+
+# FIXME: Review licenses at some point
+LICENSE="GPL-3+ GPL-2+ LGPL-3+ LGPL-2+ MIT CC-BY-SA-3.0 CC0-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="clang +devhelp doc +git gtk-doc sysprof test vala webkit"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# When bumping, pay attention to all the included plugins/*/meson.build (and other) build files and the requirements within.
+# `grep -rI dependency * --include='meson.build'` can give a good initial idea for external deps and their double checking.
+# The listed RDEPEND order shold roughly match that output as well, with toplevel one first.
+# Most plugins have no extra requirements and default to enabled; we need to handle the ones with extra requirements. Many of
+# them have optional runtime dependencies, for which we try to at least notify the user via DOC_CONTENTS (but not all small
+# things); `grep -rI -e 'command-pattern.*=' -e 'push_arg'` can give a (spammy) idea, plus python imports in try/except.
+
+# FIXME: with_flatpak needs flatpak.pc >=0.8.0, ostree-1, libsoup-2.4.pc >=2.52.0 and ${LIBGIT_DEPS}
+# Editorconfig needs old pcre, with vte migrating away, might want it optional or ported to pcre2?
+# An introspection USE flag of a dep is required if any introspection based language plugin wants to use it (grep for gi.repository). Last full check at 3.28.4
+
+# These are needed with either USE=git or USE=flatpak (albeit the latter isn't supported yet)
+LIBGIT_DEPS="
+ dev-libs/libgit2[ssh,threads]
+ >=dev-libs/libgit2-glib-0.25.0[ssh]
+"
+# TODO: Handle llvm slots via llvm.eclass; see plugins/clang/meson.build
+RDEPEND="
+ >=dev-libs/libdazzle-3.30.2[introspection,vala?]
+ >=dev-libs/glib-2.58.0:2
+ >=x11-libs/gtk+-3.24.0:3[introspection]
+ >=x11-libs/gtksourceview-4.0.0:4[introspection]
+ >=dev-libs/json-glib-1.2.0
+ >=dev-libs/jsonrpc-glib-3.30.1[vala?]
+ >=x11-libs/pango-1.38.0
+ >=dev-libs/libpeas-1.22.0[python,${PYTHON_USEDEP}]
+ >=dev-libs/template-glib-3.28.0[introspection,vala?]
+ >=x11-libs/vte-0.40.2:2.91[vala?]
+ >=dev-libs/libxml2-2.9.0
+ git? ( ${LIBGIT_DEPS} )
+ dev-libs/libpcre:3
+ webkit? ( >=net-libs/webkit-gtk-2.12.0:4=[introspection] )
+
+ >=dev-libs/gobject-introspection-1.48.0:=
+ >=dev-python/pygobject-3.22.0:3[${PYTHON_USEDEP}]
+ ${PYTHON_DEPS}
+ clang? ( sys-devel/clang:= )
+ devhelp? ( >=dev-util/devhelp-3.25.1:= )
+ sysprof? ( >=dev-util/sysprof-3.30.2[gtk] )
+ vala? (
+ dev-lang/vala:=
+ $(vala_depend)
+ )
+" # We use subslot operator dep on vala in addition to $(vala_depend), because we have _runtime_
+# usage in vala-pack plugin and need it rebuilt before removing an older vala it was built against
+# TODO: runtime ctags path finding..
+# FIXME: spellcheck plugin temporarily disabled due to requiring enchant-2
+# >=app-text/gspell-1.2.0
+# >=app-text/enchant:2
+
+# desktop-file-utils required for tests, but we have it in deptree for xdg update-desktop-database anyway, so be explicit and unconditional
+# appstream-glib needed for validation with appstream-util with FEATURES=test
+DEPEND="${RDEPEND}
+ doc? ( dev-python/sphinx )
+ test? (
+ dev-libs/appstream-glib
+ sys-apps/dbus )
+ dev-util/desktop-file-utils
+ dev-util/glib-utils
+ >=dev-util/meson-0.47.1
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+"
+
+DOC_CONTENTS='gnome-builder can use various other dependencies on runtime to provide
+extra capabilities beyond these expressed via USE flags. Some of these
+that are currently available with packages include:
+
+* dev-util/uncrustify and dev-python/autopep8 for various Code Beautifier
+ plugin out of the box functionality.
+* dev-util/ctags with exuberant-ctags selected via "eselect ctags" for
+ C, C++, Python, JavaScript, CSS, HTML and Ruby autocompletion, semantic
+ highlighting and symbol resolving support.
+* dev-python/jedi and dev-python/lxml for more accurate Python
+ autocompletion support.
+* dev-util/valgrind for integration with valgrind.
+* dev-util/meson for integration with the Meson build system.
+* dev-util/cargo for integration with the Rust Cargo build system.
+* dev-util/cmake for integration with the CMake build system.
+* net-libs/nodejs[npm] for integration with the NPM package system.
+'
+# FIXME: Package gnome-code-assistance and mention here, or maybe USE flag and default enable because it's rather important
+# eslint for additional diagnostics in JavaScript files (what package has this? At least something via NPM..)
+# jhbuild support
+# rust language server via rls; Go via go-langserver
+# autotools stuff for autotools plugin; gtkmm/autoconf-archive for C++ template
+# gjs/gettext/mono/PHPize stuff, but most of these are probably installed for other reasons anyways, when needed inside IDE
+
+llvm_check_deps() {
+ has_version "sys-devel/clang:${LLVM_SLOT}"
+}
+
+pkg_setup() {
+ python-single-r1_pkg_setup
+ use clang && llvm_pkg_setup
+}
+
+src_prepare() {
+ use vala && vala_src_prepare
+ xdg_src_prepare
+}
+
+src_configure() {
+ local emesonargs=(
+ -Denable_tracing=false
+ -Denable_profiling=false # not passing -pg to CFLAGS
+ -Dfusermount_wrapper=false # meant for flatpak builds
+ -Dwith_tcmalloc=false
+ -Dwith_channel=other
+ -Dwith_editorconfig=true # needs libpcre
+ $(meson_use webkit with_webkit)
+ $(meson_use vala with_vapi)
+ $(meson_use doc with_help)
+ $(meson_use gtk-doc with_docs)
+
+ -Dnetwork_tests=false
+ $(meson_use clang with_clang)
+ $(meson_use devhelp with_devhelp)
+ -Dwith_deviced=false
+ -Dwith_flatpak=false
+ $(meson_use git with_git)
+ $(meson_use webkit with_html_preview)
+ -Dwith_spellcheck=false # TODO: requires enchant-2
+ $(meson_use sysprof with_sysprof)
+ $(meson_use vala with_vala_pack)
+ )
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+ if use doc; then
+ rm "${ED}"/usr/share/doc/gnome-builder/en/.buildinfo || die
+ rm "${ED}"/usr/share/doc/gnome-builder/en/objects.inv || die
+ rm -r "${ED}"/usr/share/doc/gnome-builder/en/.doctrees || die
+ # custom docdir in build system, blocked by https://github.com/mesonbuild/meson/issues/825
+ mv "${ED}"/usr/share/doc/gnome-builder/en "${ED}"/usr/share/doc/${PF}/html || die
+ # _sources subdir left in on purpose, as HTML links to the rst files as "View page source". Additionally default docompress exclusion of /html/ already ensures they aren't compressed, thus linkable as-is.
+ rmdir "${ED}"/usr/share/doc/gnome-builder/ || die
+ fi
+ readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_icon_cache_update
+ gnome2_schemas_update
+ readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_icon_cache_update
+ gnome2_schemas_update
+}
+
+src_test() {
+ # FIXME: can't run meson_src_test together with virtx or dbus-run-session
+ virtx dbus-run-session meson test -C "${BUILD_DIR}"
+}
next reply other threads:[~2019-01-13 17:19 UTC|newest]
Thread overview: 58+ messages / expand[flat|nested] mbox.gz Atom feed top
2019-01-13 17:19 Mart Raudsepp [this message]
-- strict thread matches above, loose matches on Subject: below --
2025-10-18 15:13 [gentoo-commits] repo/gentoo:master commit in: dev-util/gnome-builder/ Sam James
2025-10-18 15:13 Sam James
2025-10-18 15:13 Sam James
2025-10-13 3:02 Sam James
2025-08-05 10:37 Pacho Ramos
2025-08-05 10:37 Pacho Ramos
2025-07-29 11:43 Pacho Ramos
2025-06-29 9:37 Sam James
2025-02-20 10:20 Michał Górny
2025-01-16 16:55 Pacho Ramos
2025-01-16 16:55 Pacho Ramos
2024-11-09 10:40 Pacho Ramos
2024-11-09 10:40 Pacho Ramos
2024-05-10 7:20 Mart Raudsepp
2023-11-04 23:03 Mart Raudsepp
2023-11-04 23:03 Mart Raudsepp
2023-10-29 22:23 Mart Raudsepp
2023-05-05 9:01 Arthur Zamarin
2023-04-28 16:35 Matt Turner
2023-02-06 2:40 Matt Turner
2023-02-03 16:41 Matt Turner
2023-01-27 11:52 Mart Raudsepp
2022-12-16 20:37 Arthur Zamarin
2022-12-02 14:35 Matt Turner
2022-11-16 21:17 Matt Turner
2022-11-16 16:56 Matt Turner
2022-05-08 4:22 Matt Turner
2021-10-17 21:07 Mart Raudsepp
2021-05-06 6:09 Matt Turner
2021-05-06 6:09 Matt Turner
2021-04-30 16:39 Matt Turner
2021-04-29 1:02 Matt Turner
2021-04-19 0:46 Matt Turner
2021-04-12 22:16 Matt Turner
2021-02-06 9:59 Mart Raudsepp
2020-12-08 15:41 Mart Raudsepp
2020-08-14 20:45 Mart Raudsepp
2020-08-14 20:45 Mart Raudsepp
2020-07-28 6:52 Mart Raudsepp
2020-06-27 11:48 Mart Raudsepp
2020-06-18 11:27 Mart Raudsepp
2020-05-19 7:24 Mart Raudsepp
2020-04-17 19:50 Mart Raudsepp
2020-04-13 16:12 Agostino Sarubbo
2020-04-13 14:48 Agostino Sarubbo
2020-03-14 21:08 Mart Raudsepp
2020-02-29 21:22 Mart Raudsepp
2020-02-16 10:35 Mart Raudsepp
2020-02-11 13:00 Mart Raudsepp
2020-02-05 15:00 Mart Raudsepp
2019-03-30 16:30 Mart Raudsepp
2018-12-17 15:08 Mart Raudsepp
2018-09-24 20:13 Mart Raudsepp
2018-09-12 14:39 Thomas Deutschmann
2018-04-29 0:08 Mart Raudsepp
2018-04-26 22:32 Aaron Bauman
2018-04-26 17:15 Thomas Deutschmann
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1547399762.f3f2076b9715ecffe24fbc13222d24df3ca95367.leio@gentoo \
--to=leio@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox