public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
From: "Pacho Ramos" <pacho@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-python/cgkit/
Date: Wed, 27 Jun 2018 20:52:40 +0000 (UTC)	[thread overview]
Message-ID: <1530132750.739bf1df4ed8f2aa2c3debfa49fe3214b66c1681.pacho@gentoo> (raw)

commit:     739bf1df4ed8f2aa2c3debfa49fe3214b66c1681
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Wed Jun 27 20:50:33 2018 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Wed Jun 27 20:52:30 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=739bf1df

dev-python/cgkit: Support python3.6

Package-Manager: Portage-2.3.41, Repoman-2.3.9

 dev-python/cgkit/cgkit-2.0.0-r2.ebuild | 85 ++++++++++++++++++++++++++++++++++
 1 file changed, 85 insertions(+)

diff --git a/dev-python/cgkit/cgkit-2.0.0-r2.ebuild b/dev-python/cgkit/cgkit-2.0.0-r2.ebuild
new file mode 100644
index 00000000000..b5d7cbee09c
--- /dev/null
+++ b/dev-python/cgkit/cgkit-2.0.0-r2.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+DISTUTILS_IN_SOURCE_BUILD=1
+
+inherit distutils-r1 scons-utils toolchain-funcs
+
+MY_P="${P/_/}"
+
+DESCRIPTION="Python library for creating 3D images"
+HOMEPAGE="http://cgkit.sourceforge.net"
+SRC_URI="
+	$(python_gen_cond_dep mirror://sourceforge/${PN}/${PN}/${P}/${P}-py2k.tar.gz 'python2*')
+	$(python_gen_cond_dep mirror://sourceforge/${PN}/${PN}/${P}/${P}-py3k.tar.gz 'python3*')"
+
+LICENSE="LGPL-2.1 MPL-1.1 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="3ds"
+
+RDEPEND="
+	>=dev-libs/boost-1.48[python,${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/pyprotocols[${PYTHON_USEDEP}]' 'python2*')
+	dev-python/pyopengl[${PYTHON_USEDEP}]
+	dev-python/pygame[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	3ds? ( ~media-libs/lib3ds-1.3.0 )"
+DEPEND="${RDEPEND}"
+
+src_unpack() {
+	cgkit_unpack() {
+		local tarball
+		if python_is_python3; then
+			tarball=${P}-py3k.tar.gz
+		else
+			tarball=${P}-py2k.tar.gz
+		fi
+		mkdir "${BUILD_DIR}" || die
+		tar -C "${BUILD_DIR}" -x --strip-components 1 -f "${DISTDIR}/${tarball}" || die
+	}
+	python_foreach_impl cgkit_unpack
+	mkdir "${S}" || die
+}
+
+python_prepare() {
+	eapply \
+		"${FILESDIR}"/${PN}-2.0.0-fix-build-system.patch \
+		"${FILESDIR}"/${PN}-2.0.0-fix-c++14.patch
+	if python_is_python3; then
+		eapply "${FILESDIR}"/${PN}-py3k-pillow.patch
+	else
+		eapply "${FILESDIR}"/${PN}-py2k-pillow.patch
+	fi
+
+	cp config_template.cfg config.cfg || die
+	cat >> config.cfg <<- _EOF_ || die
+		BOOST_LIB = 'boost_python-${EPYTHON#python}'
+		LIBS += ['GL', 'GLU', 'glut']
+		LIB3DS_AVAILABLE = $(usex 3ds True False)
+	_EOF_
+
+	# Remove invalid test
+	rm -f unittests/test_pointcloud.py || die
+}
+
+python_configure_all() {
+	tc-export AR CXX
+}
+
+python_compile() {
+	pushd supportlib >/dev/null || die
+	CXXFLAGS="${CXXFLAGS} -fPIC" escons
+	popd >/dev/null || die
+	distutils-r1_python_compile
+}
+
+python_test() {
+	pushd unittests >/dev/null || die
+	mkdir tmp || die
+	"${EPYTHON}" all.py || die "Testing failed with ${EPYTHON}"
+	popd >/dev/null || die
+}


             reply	other threads:[~2018-06-27 20:52 UTC|newest]

Thread overview: 9+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2018-06-27 20:52 Pacho Ramos [this message]
  -- strict thread matches above, loose matches on Subject: below --
2019-07-27  7:54 [gentoo-commits] repo/gentoo:master commit in: dev-python/cgkit/ Andreas Sturmlechner
2018-07-24  0:38 Mikle Kolyada
2018-07-21  0:06 Mikle Kolyada
2018-06-27 20:52 Pacho Ramos
2017-05-02  9:48 Michał Górny
2017-03-22  7:43 Michael Weber
2017-03-11 13:42 Agostino Sarubbo
2017-03-11 13:31 Agostino Sarubbo

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=1530132750.739bf1df4ed8f2aa2c3debfa49fe3214b66c1681.pacho@gentoo \
    --to=pacho@gentoo.org \
    --cc=gentoo-commits@lists.gentoo.org \
    --cc=gentoo-dev@lists.gentoo.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox