From: "Austin English" <wizardedit@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: games-strategy/defcon-demo/
Date: Thu, 7 Sep 2017 21:05:22 +0000 (UTC) [thread overview]
Message-ID: <1504818256.f9e3f47429bf581bac277323e4d5cfe3012da3c1.wizardedit@gentoo> (raw)
commit: f9e3f47429bf581bac277323e4d5cfe3012da3c1
Author: Austin English <wizardedit <AT> gentoo <DOT> org>
AuthorDate: Thu Sep 7 18:11:04 2017 +0000
Commit: Austin English <wizardedit <AT> gentoo <DOT> org>
CommitDate: Thu Sep 7 21:04:16 2017 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f9e3f474
games-strategy/defcon-demo: remove deprecated games eclass
Also update to EAPI 6
Gentoo-Bug: https://bugs.gentoo.org/574082
Package-Manager: Portage-2.3.6, Repoman-2.3.2
.../defcon-demo/defcon-demo-1.60-r1.ebuild | 96 ++++++++++++++++++++++
1 file changed, 96 insertions(+)
diff --git a/games-strategy/defcon-demo/defcon-demo-1.60-r1.ebuild b/games-strategy/defcon-demo/defcon-demo-1.60-r1.ebuild
new file mode 100644
index 00000000000..486a654236b
--- /dev/null
+++ b/games-strategy/defcon-demo/defcon-demo-1.60-r1.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils toolchain-funcs gnome2-utils
+
+MY_PN=defcon
+MY_PV=${PV:0:3}
+MY_PVR=1
+MY_P=defcon_${MY_PV}-${MY_PVR}
+
+DESCRIPTION="Global thermonuclear war simulation with multiplayer support"
+HOMEPAGE="http://www.introversion.co.uk/defcon/"
+SRC_URI="x86? ( http://www.introversion.co.uk/defcon/downloads/${MY_P}_i386.deb )
+ amd64? ( http://www.introversion.co.uk/defcon/downloads/${MY_P}_amd64.deb )"
+
+LICENSE="Introversion"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+IUSE="+system-libs"
+RESTRICT="mirror strip"
+
+# glibc discussion:
+# http://forums.introversion.co.uk/defcon/viewtopic.php?t=4016
+RDEPEND="
+ media-libs/libogg
+ media-libs/libvorbis
+ >=sys-libs/glibc-2.3
+ x11-libs/libX11
+ x11-libs/libXau
+ x11-libs/libXdmcp
+ x11-libs/libXext
+ system-libs? ( media-libs/libsdl[sound,video] )"
+DEPEND=""
+
+QA_PREBUILT="/opt/${PN}/lib/${MY_PN}.bin.x86"
+
+S="${WORKDIR}/usr/local/games/${MY_PN}"
+
+src_unpack() {
+ default
+ unpack ./data.tar.gz
+
+ cd "${S}" || die
+ # maintain compatibility with old installation/script
+ [[ -e lib64 ]] && { mv lib64 lib || die ;}
+ [[ -e ${MY_PN}.bin.x86_64 ]] && { mv ${MY_PN}.bin.x86_64 ${MY_PN}.bin.x86 || die ;}
+}
+
+src_prepare() {
+ default
+
+ # FindPath scripts are ugly and unnecessary
+ if use system-libs ; then
+ rm -f lib/lib*
+ fi
+ sed \
+ -e "s:GAMEDIR:/opt/${PN}:g" \
+ "${FILESDIR}"/${MY_PN} > "${T}"/${MY_PN} || die
+ echo "int chdir(const char *d) { return 0; }" > chdir.c || die
+}
+
+src_compile() {
+ echo "$(tc-getCC) ${CFLAGS} ${LDFLAGS} -fPIC -shared -o lib/chdir.so chdir.c"
+ $(tc-getCC) ${CFLAGS} ${LDFLAGS} -fPIC -shared -o lib/chdir.so chdir.c || die
+}
+
+src_install() {
+ local dir="/opt/${PN}"
+
+ insinto "${dir}/lib"
+ doins *.dat
+
+ exeinto "${dir}"/lib
+ doexe lib/*.so
+ doexe ${MY_PN}.bin.x86
+
+ doicon -s 128 ${MY_PN}.png
+
+ # Can be upgraded to full version, so is not installed as "demo"
+ dobin "${T}"/${MY_PN}
+ make_desktop_entry ${MY_PN} "Defcon"
+}
+
+pkg_preinst() {
+ gnome2_icon_savelist
+}
+
+pkg_postinst() {
+ gnome2_icon_cache_update
+ elog "Screenshots will appear in ~/.${MY_PN}/lib"
+}
+
+pkg_postrm() {
+ gnome2_icon_cache_update
+}
next reply other threads:[~2017-09-07 21:05 UTC|newest]
Thread overview: 4+ messages / expand[flat|nested] mbox.gz Atom feed top
2017-09-07 21:05 Austin English [this message]
-- strict thread matches above, loose matches on Subject: below --
2019-09-23 17:16 [gentoo-commits] repo/gentoo:master commit in: games-strategy/defcon-demo/ Michał Górny
2017-12-21 1:57 David Seifert
2015-12-29 20:32 Michael Sterrett
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1504818256.f9e3f47429bf581bac277323e4d5cfe3012da3c1.wizardedit@gentoo \
--to=wizardedit@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox