[gentoo-commits] repo/gentoo:master commit in: net-im/profanity/

["Sam James" <sam@gentoo.org>]

commit:     a1d58e9bcdfa2862c55a97627dda773fa70ca026
Author:     マリウス <marius <AT> xn--gckvb8fzb <DOT> com>
AuthorDate: Fri Jul 11 19:15:10 2025 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Jul 18 19:20:11 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a1d58e9b

net-im/profanity: Bump to 0.15.0

[sam: Added Closes tag.]

Closes: https://bugs.gentoo.org/960401
Signed-off-by: マリウス <marius <AT> xn--gckvb8fzb.com>
Part-of: https://github.com/gentoo/gentoo/pull/42951
Closes: https://github.com/gentoo/gentoo/pull/42951
Signed-off-by: Sam James <sam <AT> gentoo.org>

 net-im/profanity/Manifest                |  1 +
 net-im/profanity/profanity-0.15.0.ebuild | 87 ++++++++++++++++++++++++++++++++
 2 files changed, 88 insertions(+)

diff --git a/net-im/profanity/Manifest b/net-im/profanity/Manifest
index 944d1faf3e24..143ca2bd3047 100644
--- a/net-im/profanity/Manifest
+++ b/net-im/profanity/Manifest
@@ -3,3 +3,4 @@ DIST profanity-0.14.0-ox-carbons.patch 1525 BLAKE2B 85fe9a76a8c735047365d56555c8
 DIST profanity-0.14.0-plugins-install.patch 2295 BLAKE2B 8b67718abdb620875b9040f550685189acf5a2776aa5f45422e3471c13ae05bd773c05652048940d5b8d10d88c9a013c3262742db7c84b0ff0c108f5f78ead45 SHA512 a8912d5a33d4d6eebf85733f616ed729a05688b4acf70c927aa733755527fd4e523c3a485bbb0390b2006225e8420e1d76db7e91d2122af41496c0081e3b0cea
 DIST profanity-0.14.0-xscreensaver.patch 1678 BLAKE2B fe350b2249e45224b6510bb5730f38eafeb47e60a44035eaf88771940c9f0e556cc72ca737cb68c0b148b9faff442b9c9b6cdf9169a3db7ff6c7a60c2bdfc025 SHA512 2875df728b9957fc3bc8734a87c0e1a48913170b9718d6664ea65187327e26da1a7b2f5b80fe243a5ce5ab74983e4f3d22113747f44f8b8e8c13c871d31cf651
 DIST profanity-0.14.0.tar.gz 936272 BLAKE2B ec2ae625950a838ee50d6d3a87910bec76f28777bd662e909f394f18c277662694611a59d3be6c7f66821c2800a94b08f94b27a68d82e4de33b7d2f7b14ddf18 SHA512 25afd2f3146e6ed9f573f0e073cad0f06f7f8a21441c3c2c61641442d1aa5b9a7a817cdccc17354b32045ab9a965a95495a30c49088577a5060e8969725ea86e
+DIST profanity-0.15.0.tar.gz 967651 BLAKE2B f9767ca2fd1297ba9f31d608cf0af7fbe440f3915ce3cc9180321a11fd8461222b92bf859f590397c612342c85dbd6cd9393e1b3ae6f5b5847c0dd0ca176ada6 SHA512 e7fc08049b19c5d9295f5254a965995634780a7ab31388f70202e3fa19721d5d049d8402b79cfdfa4ac141f760fc1e8b4bce9ff8634a8669687a78f67657fac6

diff --git a/net-im/profanity/profanity-0.15.0.ebuild b/net-im/profanity/profanity-0.15.0.ebuild
new file mode 100644
index 000000000000..4bc69de0958b
--- /dev/null
+++ b/net-im/profanity/profanity-0.15.0.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+inherit flag-o-matic python-single-r1
+
+DESCRIPTION="A console based XMPP client inspired by Irssi"
+HOMEPAGE="https://profanity-im.github.io"
+SRC_URI="
+	https://github.com/profanity-im/profanity/releases/download/${PV}/${P}.tar.gz
+"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="libnotify omemo omemo-qrcode otr gpg test xscreensaver python"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="omemo-qrcode? ( omemo ) python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	>=dev-libs/libstrophe-0.12.3:=
+	media-libs/harfbuzz:=
+	net-misc/curl
+	sys-libs/ncurses:=[unicode(+)]
+	sys-libs/readline:=
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/pango
+	x11-misc/shared-mime-info
+	gpg? ( app-crypt/gpgme:= )
+	libnotify? ( x11-libs/libnotify )
+	omemo? (
+		dev-libs/libgcrypt:=
+		net-libs/libsignal-protocol-c
+	)
+	omemo-qrcode? ( media-gfx/qrencode:= )
+	otr? ( net-libs/libotr )
+	python? ( ${PYTHON_DEPS} )
+	xscreensaver? (
+		x11-libs/libXScrnSaver
+		x11-libs/libX11
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-util/cmocka )
+	python? (
+		$(python_gen_cond_dep '
+			dev-python/cython[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-gdk-pixbuf
+		$(use_enable libnotify notifications)
+		$(use_enable omemo)
+		$(use_enable omemo-qrcode)
+		$(use_enable otr)
+		$(use_enable python python-plugins)
+		$(use_enable gpg pgp)
+		$(use_with xscreensaver)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake CFLAGS="${CFLAGS}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -type f -name '*.la' -delete || die
+}