[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel/

["Michał Górny" <mgorny@gentoo.org>]

commit:     2fe87c1c38bac29dfc500d69a407ccd5413cf01c
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Feb  2 15:37:33 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Feb  3 05:37:13 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2fe87c1c

sys-kernel/gentoo-kernel: Bump to 4.19.101

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 sys-kernel/gentoo-kernel/Manifest                  |  2 +
 .../gentoo-kernel/gentoo-kernel-4.19.101.ebuild    | 76 ++++++++++++++++++++++
 2 files changed, 78 insertions(+)

diff --git a/sys-kernel/gentoo-kernel/Manifest b/sys-kernel/gentoo-kernel/Manifest
index aa278b5b106..d59d4372df3 100644
--- a/sys-kernel/gentoo-kernel/Manifest
+++ b/sys-kernel/gentoo-kernel/Manifest
@@ -1,3 +1,5 @@
+DIST genpatches-4.19-100.base.tar.xz 2992824 BLAKE2B 02722c5568726284afa812be3d9cb4555bad11133dd5876d8ee09771e584e73dfb6e7bd8a2829126ff2dada931856a07429715a918a0fe88786fa98fb6ad6edb SHA512 621a9294c3377720723e89b175bb4f0f2812e566b73952a81112bc1ef675862842e00f642ba37f728ae8aa0e5e5cc17b347cea564821c02c88c532668007b5cc
+DIST genpatches-4.19-100.extras.tar.xz 17492 BLAKE2B c896c916f2dfad38b35f1ebd080cb5b66f6bd51b28a77535fc2ae44b11a1a5bee1be52a7d6d5e30b80c635b59e43f40d99c2cea98cf0744374412626a939cc00 SHA512 169dea4d9c41057807c63a8d66aa7fb94d783e841a94a700bc0eb1995e620e6b529658d3899ffc54e5cfde4e9267e385dc2e36786ff0c31acecc0593456f8909
 DIST genpatches-4.19-95.base.tar.xz 2780232 BLAKE2B cc5ba5e36acb8834ca2313ec134ad4156b543cfda08f08677b5f6efcda8a7b5b9bcdc70691e33698af1e81a9e381916bd5e41e2c5218c2930a928df82d44b7fd SHA512 5f935cc3cd1ecafaeca148010b28d0742dcbbf50d28f77ae1255016548fe921a83befcf577a52553f161cfa54da2c9df204abbbc2004378bc0f8ac58fbafdf04
 DIST genpatches-4.19-95.extras.tar.xz 17492 BLAKE2B 5138c0138058e5dde744a056bf5068cc1db98cd3a52375d30ca72007d89d5c2b87e1493f1c3cc83cc7d0f1f489783ddf98f1b6d76b33ced4a7f18ae13e1b61cc SHA512 a1d5428a4aa5484dd26e4548a8796f54884541d4012e7591e0bf3c5f63fd9af242fa1719c5bda8e956e0be69f207adedfd0061ccbc00963ceb1272c03edb0e1a
 DIST genpatches-4.19-96.base.tar.xz 2796188 BLAKE2B 6f8506b0a275b8ae1d215fe4d3812a5d895c05f07db16f560e6cfb8d4945e9a9bc10afcf537c165f96fc111657ba2191c6720be15a49726e92cf6277f9aa1e5d SHA512 62334fd0c23acbbf3c0bfcecc6970501b7c500e24e628130e2d541b29363782757feb3b915e9b3d1210c538fde87d9eb6b64694af5110d55789efd29c8ccce5e

diff --git a/sys-kernel/gentoo-kernel/gentoo-kernel-4.19.101.ebuild b/sys-kernel/gentoo-kernel/gentoo-kernel-4.19.101.ebuild
new file mode 100644
index 00000000000..3b0d137453f
--- /dev/null
+++ b/sys-kernel/gentoo-kernel/gentoo-kernel-4.19.101.ebuild
@@ -0,0 +1,76 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-build
+
+MY_P=linux-4.19.94
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} - 1))
+# https://git.archlinux.org/svntogit/packages.git/log/trunk/config?h=packages/linux-lts
+AMD64_CONFIG_VER=4.19.92-arch1
+AMD64_CONFIG_HASH=bf97de6a2e405659aaad4c251b7f0bb48d5ed3c9
+# https://git.archlinux32.org/packages/log/core/linux-lts/config
+I686_CONFIG_VER=4.19.85-arch1
+I686_CONFIG_HASH=1f0345e2983d2edd55b401cb5a87fdf365a4192c
+
+DESCRIPTION="Linux kernel built with Gentoo patches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+=" https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	amd64? (
+		https://git.archlinux.org/svntogit/packages.git/plain/trunk/config?h=packages/linux-lts&id=${AMD64_CONFIG_HASH}
+			-> linux-${AMD64_CONFIG_VER}.amd64.config
+	)
+	x86? (
+		https://git.archlinux32.org/packages/plain/core/linux-lts/config?id=${I686_CONFIG_HASH}
+			-> linux-${I686_CONFIG_VER}.i686.config
+	)"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	!sys-kernel/vanilla-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel-bin:${SLOT}"
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		# (skip most patch release patches, we just fetch newer sources)
+		"${WORKDIR}"/109[4-9]*.patch
+		"${WORKDIR}"/11*.patch
+		"${WORKDIR}"/[2-9]*.patch
+	)
+	default
+
+	# prepare the default config
+	case ${ARCH} in
+		amd64)
+			cp "${DISTDIR}"/linux-${AMD64_CONFIG_VER}.amd64.config .config || die
+			;;
+		x86)
+			cp "${DISTDIR}"/linux-${I686_CONFIG_VER}.i686.config .config || die
+			;;
+		*)
+			die "Unsupported arch ${ARCH}"
+			;;
+	esac
+
+	local config_tweaks=(
+		# shove arch under the carpet!
+		-e 's:^CONFIG_DEFAULT_HOSTNAME=:&"gentoo":'
+		# we do support x32
+		-e '/CONFIG_X86_X32/s:.*:CONFIG_X86_X32=y:'
+		# disable signatures
+		-e '/CONFIG_MODULE_SIG/d'
+		-e '/CONFIG_SECURITY_LOCKDOWN/d'
+		# disable compression to allow stripping
+		-e '/CONFIG_MODULE_COMPRESS/d'
+		# disable gcc plugins to unbreak distcc
+		-e '/CONFIG_GCC_PLUGIN_STRUCTLEAK/d'
+	)
+	sed -i "${config_tweaks[@]}" .config || die
+}